InterlockedCompareExchangePointer with Delphi string - multithreading

Question

In my server code I use the following pattern for creating "just in time" objects:
function TSomeObject.GetChildObjects: TChildObjects;
var
ChildObjects: TChildObjects;
begin
if FChildObjects=nil then
begin
ChildObjects:=TChildObjects.Create;
// Fill child objects here
if InterlockedCompareExchangePointer(Pointer(FChildObjects),ChildObjects,nil) <> nil then
ChildObjects.Free;
end;
result:=FChildObjects;
end;
This works fine, but how would I do something similar with Delphi strings? e.g. if I wanted to initialise a string "just in time" in a multi threaded envrionment? Or do I have to use a critical section? e.g:
function TSomeObject.GetSomeString: string;
var
s :string;
begin
if FSomeString='' then
begin
s:='Test';
// InterlockedCompareExchangePointer(Pointer(FSomeString),s,nil);
end;
result:=FSomeString;
end;

Answer 1

Strings are reference counted, so it is not enough to just swap the pointers, you have to manage the reference counts too, eg:
function GetStrRec(const S: string): PStrRec; inline;
begin
Result := PStrRec(PByte(S) - SizeOf(StrRec));
end;
function InterlockedCompareExchangeString(var VTarget: String; const AValue, Compare: String): String; inline;
var
P: PStrRec;
begin
Result := '';
if AValue <> '' then begin
P := GetStrRec(AValue);
if P.refCnt > -1 then AtomicIncrement(P.refCnt);
end;
Pointer(Result) := InterlockedCompareExchangePointer(Pointer(VTarget), Pointer(AValue), Pointer(Compare));
if Pointer(Result) <> Pointer(Compare) then begin
if Result <> '' then begin
P := GetStrRec(Result);
if P.refCnt > -1 then AtomicIncrement(P.refCnt);
end;
if AValue <> '' then begin
P := GetStrRec(AValue);
if P.refCnt > -1 then AtomicDecrement(P.refCnt);
end;
end;
end;
Alternatively:
function GetStrRec(const S: string): PStrRec; inline;
begin
Result := PStrRec(PByte(S) - SizeOf(StrRec));
end;
function InterlockedCompareExchangeString(var VTarget: String; const AValue, Compare: String): String; inline;
var
P: PStrRec;
begin
Result := '';
Pointer(Result) := InterlockedCompareExchangePointer(Pointer(VTarget), Pointer(AValue), Pointer(Compare));
if Pointer(Result) = Pointer(Comparand) then
begin
if AValue <> '' then begin
P := GetStrRec(AValue);
if P.refCnt > -1 then AtomicIncrement(P.refCnt);
end;
end
else if Result <> '' then begin
P := GetStrRec(Result);
if P.refCnt > -1 then AtomicIncrement(P.refCnt);
end;
end;
Unfortunately, the RTL doesn't expose functions to manipulate a string's reference count, only to query it (StringRefCount()), which is why you have to access and manipulate the string's inner StrRec header manually.