groovy sed error sed: -e expression #1, char 1: unknown command: `'' - groovy

Question

Groovy code is :
def cmd = "sed -i \'1 i <?xml version=\"1.1\"?>\' test.xml"
println cmd
println cmd.execute().err.text
Output:
sed -i '1 i <?xml version="1.1"?>' test.xml
sed: -e expression #1, char 1: unknown command: `''
Here is the actual command sed -i '1 i <?xml version="1.1"?>' test.xml that runs well in cli. But Groovy execute() does not work correctly. How to fix this ?
Update 1 :
Also tried with the below cmd, butstill shows same error.
def cmd = /sed -i '1 i <?xml version="1.1"?>' test.xml/
def cmd = "sed -i '1 i <?xml version=\"1.1\"?>' test.xml"
Update Note:
To check and update an xml file,
def insertversion(String filename)
{
def lines= new File (filename).readLines()
if(!(lines.get(0)).contains('xml version'))
{
def cmd = ['sed', '-i', '1 i <?xml version="1.1"?>', filename]
cmd.execute()
}
}

Answer 1

In this case execute shell command as a list of cmd and parameters instead of a executing command as String:
def cmd = ['sed', '-i', '1 i <?xml version="1.1"?>', 'test.xml']
println cmd
println cmd.execute().err.text
After running script like this part <?xml version="1.1"> gets duplicated in test.xml file (same behavior as running given command from command line).
What is the difference between List.execute() and String.execute()?
If you execute shell command as a String, java.lang.Runtime.exec() method will use java.util.StringTokenizer to split your input String into an array. In your case tokenizer will create 7 tokens, you can check it by running following script:
def cmd = "sed -i \'1 i <?xml version=\"1.1\"?>\' test.xml"
def tokenizer = new StringTokenizer(cmd)
def tokens = []
while (tokenizer.hasMoreTokens()) {
tokens << tokenizer.nextToken()
}
tokens.each { println it }
It outputs:
sed
-i
'1
i
<?xml
version="1.1"?>'
test.xml
You can also verify it by running debugger with a checkpoint set in java.lang.Runtime class at line 96:
This is of course incorrect. When using a list to execute shell command we will get correct array of command line parameters:
The general rule of thumb is that if your shell command contains characters that may confuse java.util.StringTokenizer it's better to use a list to define correct list of command line parameters.