Importing Spreedsheet file from SAP GUI using Macro - VBA error 9 subscript out of range while using Workbooks.Close - excel

Question

I'm newbie into macros and VBA - but because specific of my work requires to learn about VBA and macros.
So I've recorded in SAP GUI code below.
File EXPORT.XLSX saves at destination and new EXPORT.XLSX opens itself - But I want to just save it at the destination - without opening it straight away (for that I have different code) - how to do it? Or how to close the EXPORT.XLSX - Workbooks("filenamewithpath").close doesn't work - I'm receiving Error Code 9 :/
Run-time error '9': Subscript out of range
Sub Pobierz_zle()
If Not IsObject(SApplication) Then
Set SapGuiAuto = GetObject("SAPGUI")
Set SApplication = SapGuiAuto.GetScriptingEngine
End If
If Not IsObject(Connection) Then
Set Connection = SApplication.Children(0)
End If
If Not IsObject(session) Then
Set session = Connection.Children(0)
End If
If IsObject(WScript) Then
WScript.ConnectObject session, "on"
WScript.ConnectObject SApplication, "on"
End If
session.findById("wnd[0]").maximize
session.findById("wnd[0]/tbar[0]/okcd").Text = "/n zle_stocklist"
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/ctxt[0]").Text = "3901"
session.findById("wnd[0]/usr/ctxt[0]").caretPosition = 4
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/ctxt[1]").Text = "3182"
session.findById("wnd[0]/usr/ctxt[1]").caretPosition = 4
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/ctxt[3]").Text = "3500"
session.findById("wnd[0]/usr/ctxt[3]").SetFocus
session.findById("wnd[0]/usr/ctxt[3]").caretPosition = 4
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]/usr/chk[0]").Selected = False
session.findById("wnd[0]/usr/chk[0]").SetFocus
session.findById("wnd[0]").sendVKey 0
session.findById("wnd[0]").sendVKey 8
session.findById("wnd[0]/usr/cntlCONTAINER_1/shellcont/shell").pressToolbarContextButton "&MB_EXPORT"
session.findById("wnd[0]/usr/cntlCONTAINER_1/shellcont/shell").selectContextMenuItem "&XXL"
session.findById("wnd[1]/usr/cmb").SetFocus
session.findById("wnd[1]/tbar[0]/btn[0]").press
session.findById("wnd[1]/usr/ctxt[0]").Text = "T:\DEPT-TSCW\WL\Inwentaryzacja\TEMP\"
session.findById("wnd[1]/usr/ctxt[1]").Text = "EXPORT.XLSX"
session.findById("wnd[1]/usr/ctxt[1]").caretPosition = 11
session.findById("wnd[1]").sendVKey 0
Application.Wait (Now + TimeValue("0:00:10"))
ActiveWorkbook.Close (False)
End Sub

Answer 1

Based on this entry you could try the following
Add the following declarations to a module
Option Explicit
' https://stackoverflow.com/a/68004477/6600940
#If VBA7 Then
Private Declare PtrSafe Function FindWindowEx Lib "User32" Alias _
"FindWindowExA" (ByVal hWnd1 As LongPtr, _
ByVal hWnd2 As LongPtr, ByVal lpsz1 As String, _
ByVal lpsz2 As String) As LongPtr
Private Declare PtrSafe Function IIDFromString Lib "ole32" _
(ByVal lpsz As LongPtr, ByRef lpiid As GUID) As LongPtr
Private Declare PtrSafe Function AccessibleObjectFromWindow Lib "oleacc" _
(ByVal hWnd As LongPtr, ByVal dwId As LongPtr, ByRef riid As GUID, _
ByRef ppvObject As Object) As LongPtr
#Else
Private Declare Function FindWindowEx Lib "User32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, _
ByVal lpsz2 As String) As Long
Private Declare Function IIDFromString Lib "ole32" _
(ByVal lpsz As Long, ByRef lpiid As GUID) As Long
Private Declare Function AccessibleObjectFromWindow Lib "oleacc" _
(ByVal hWnd As Long, ByVal dwId As Long, ByRef riid As GUID, _
ByRef ppvObject As Object) As Long
#End If
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type
Private Const S_OK As Long = &H0
Private Const IID_IDispatch As String = "{00020400-0000-0000-C000-000000000046}"
Private Const OBJID_NATIVEOM As Long = &HFFFFFFF0
As you have the name of the workbook you would like to close you can run the following code. It will counter-times look for that file and try to close it. It might be not the perfect solution but for me it works all the time. Whenever I donwload a file from SAP it will close the automatically opened file regardless wheter it was opened in the same instance or in another one
Sub runCloseWorkbook(wkbName As String, counter As Long)
Const MAX_TRIES As Long = 10
If closeWorkbook(wkbName) Then
Exit Sub
Else
counter = counter + 1
If counter <= MAX_TRIES Then
Application.OnTime Now + TimeValue("00:00:05"), "'runCloseWorkbook """ & wkbName & """,""" & counter & "'"
'Debug.Print "closeWorkbook", wkbName, counter
End If
End If
End Sub
For getting this to work you also need
Private Function closeWorkbook(wkbName As String) As Boolean
Dim hWinXL As Long
hWinXL = FindWindowEx(0&, 0&, "XLMAIN", vbNullString)
Dim xlApp As Excel.Application
Dim wb As Excel.Workbook
Do While hWinXL > 0
If getXLApp(hWinXL, xlApp) Then
For Each wb In xlApp.Workbooks
If wb.Name = wkbName Then
wb.Close False
closeWorkbook = True
' xlApp.Quit
End If
Next
End If
hWinXL = FindWindowEx(0, hWinXL, "XLMAIN", vbNullString)
Loop
End Function
' Private Function getXLApp(hWinXL As Long, xlApp As Excel.Application) As Boolean
Function getXLApp(hWinXL As Long, xlApp As Object) As Boolean
Dim hWinDesk As Long, hWin7 As Long
Dim obj As Object
Dim iid As GUID
Call IIDFromString(StrPtr(IID_IDispatch), iid)
hWinDesk = FindWindowEx(hWinXL, 0&, "XLDESK", vbNullString)
hWin7 = FindWindowEx(hWinDesk, 0&, "EXCEL7", vbNullString)
If AccessibleObjectFromWindow(hWin7, OBJID_NATIVEOM, iid, obj) = S_OK Then
Set xlApp = obj.Application
getXLApp = True
End If
End Function
In your case you could call it like that
runcloseworkbook "T:\DEPT-TSCW\WL\Inwentaryzacja\TEMP\EXPORT.XLSX", 5