Deleting custom styles in Excel workbook - excel

Question

I am working in a large xlsb (Microsoft Excel Binary Workbook) and have noticed that there is a very large number of custom styles saved in the file. I think the styles were all unintentionally included in the file when worksheets were copied in from other workbooks. I would like to delete all of the custom styles but the manual approach (right click and delete) doesn't work. I then searched online for VBA solutions and found the three macros below but these doesn't work either. When I run the macros they just immediately jump to the MsgBox without having deleted any of the custom styles. Hopefully someone here can shed some light on how I can either reconfigure the macros or direct me towards another solution. -> See updated info below!
Sub clear_all_styles()
Dim styT As Style
On Error Resume Next
For Each styT In ActiveWorkbook.Styles
If Not styT.BuiltIn Then
If styT.Name <> "1" Then styT.Delete
End If
Next styT
MsgBox "Macro completed" 'can be commented out
End Sub
.
Sub DeleteStyles()
On Error Resume Next
For Each sty In ActiveWorkbook.Styles
If Not sty.BuiltIn Then
sty.Delete
End If
Next sty
MsgBox "Macro completed" 'can be commented out
End Sub
.
Sub StyleKiller()
Dim st As Style
On Error Resume Next
For Each st In ActiveWorkbook.Styles
If Not st.BuiltIn Then
st.Delete
End If
Next
On Error GoTo 0
MsgBox "Macro completed" 'can be commented out
End Sub
Updated Info: After searching more solution online (generally, none of these worked) I finally found a larger solution which worked (included below). This solution deleted the vast majority of the custom styles but approx. 20 styles remain which cant be deleted by the macro nor by manual action. I notice that all of these remaining custom styles seem to have special signs in them and I'm wondering if that's the reason they can't be deleted. If anyone can provide any guidance on this is would be much appreciated!
Sub RebuildDefaultStyles()
'The purpose of this macro is to remove all styles in the active
'workbook and rebuild the default styles.
'It rebuilds the default styles by merging them from a new workbook.
'Dimension variables.
Dim MyBook As Workbook
Dim tempBook As Workbook
Dim CurStyle As Style
'Set MyBook to the active workbook.
Set MyBook = ActiveWorkbook
On Error Resume Next
'Delete all the styles in the workbook.
For Each CurStyle In MyBook.Styles
'If CurStyle.Name <> "Normal" Then CurStyle.Delete
Select Case CurStyle.Name
Case "20% - Accent1", "20% - Accent2", _
"20% - Accent3", "20% - Accent4", "20% - Accent5", "20% - Accent6", _
"40% - Accent1", "40% - Accent2", "40% - Accent3", "40% - Accent4", _
"40% - Accent5", "40% - Accent6", "60% - Accent1", "60% - Accent2", _
"60% - Accent3", "60% - Accent4", "60% - Accent5", "60% - Accent6", _
"Accent1", "Accent2", "Accent3", "Accent4", "Accent5", "Accent6", _
"Bad", "Calculation", "Check Cell", "Comma", "Comma [0]", "Currency", _
"Currency [0]", "Explanatory Text", "Good", "Heading 1", "Heading 2", _
"Heading 3", "Heading 4", "Input", "Linked Cell", "Neutral", "Normal", _
"Note", "Output", "Percent", "Title", "Total", "Warning Text"
'Do nothing, these are the default styles
Case Else
CurStyle.Delete
End Select
Next CurStyle
'Open a new workbook.
Set tempBook = Workbooks.Add
'Disable alerts so you may merge changes to the Normal style
'from the new workbook.
Application.DisplayAlerts = False
'Merge styles from the new workbook into the existing workbook.
MyBook.Styles.Merge Workbook:=tempBook
'Enable alerts.
Application.DisplayAlerts = True
'Close the new workbook.
tempBook.Close
End Sub

Answer 1

perhapst deleting by a subroutine gives more information:
Option Explicit
Sub DelStyles()
Dim st As Style
For Each st In ActiveWorkbook.Styles
If Not st.BuiltIn Then
DelSingleStyle st
End If
Next
End Sub
Sub DelSingleStyle(st As Style)
On Error GoTo BadStyle
Dim s As String
s = st.Name
Debug.Print " Try to delete: "; s
st.Delete
Debug.Print " Deleted: "; s
Exit Sub
BadStyle:
Debug.Print "Not Deleted: "; st.Name
End Sub

Answer 2

With a minor modification of one of the Sub's you list above, all styles, including built-in styles (except "Normal", which cannot be deleted) are removed from the WorkBook.
Sub DeleteStyles()
Dim sty As Style
'On Error Resume Next 'outcommented as it is not needed
For Each sty In ActiveWorkbook.Styles
'If Not sty.BuiltIn Then 'outcommented as all styles should be deleted
If sty.Name <> "Normal" Then 'except Normal, which cannot be deleted
sty.Delete
End If
Next sty
MsgBox "Macro completed" 'can be commented out
End Sub
You never answered to my question what you mean with "Special signs", but if you meant the % sign that occurs in some of the built-in styles, that is only the percentage (surprise!) of the color fill, e.g. "20% - Accent1" meaning a light fill.