Why is my Index Match generating an error? VBA - excel

Question

Am I performing the Index Match function in the wrong location?
Should I even be using IndexMatch?
My information in the table I am trying to get the information out of has CO number in column A.
Columns B has the information I am trying to populate my new worksheet with.
Sub AddWorkbooks()
Dim ChangeOrder As Range
Dim XCXX As Worksheet
Dim wb As Workbook
Dim CoForm As Worksheet
Dim CoFormCopy As Worksheet
Dim srNO As Variant
Set wb = ActiveWorkbook
Set XCXX = ActiveSheet
Set CoForm = wb.Worksheets("+CO Form+")
'Set wbNew = Workbooks.Add
srNO = XCXX.Range("D2").Value
'CoForm.Copy After:=Sheets(ActiveSheet.Index)
CoForm.Copy After:=XCXX
ActiveSheet.Name = "Proj" & " " & XCXX.Range("D2").Value
Set CoFormCopy = XCXX.Next 'the copy of +CO Form
With CoFormCopy
'Adds CO Number
Range("A6:D6").Value = XCXX.Range("D2").Value
'Adds CO Description from CO_List sheet based on CO Number
Range("A16").Value = Application.WorksheetFunction.Index(Sheets("CO_List").Range("B3:B"), Application.WorksheetFunction.Match(srNO, Sheets("CO_List").Range("A3:A"), 0))
'ActiveCell.FormulaR1C1 = XCXX.Range("D2").Value
End With
CoFormCopy.Move
End Sub

Answer 1

If no match is found WorksheetFunction.Match will fail. Application.Match will return #N/A error that you can test for with IsError().
Option Explicit
Sub AddWorkbooks()
Dim wb As Workbook, wbNew As Workbook
Dim srNo, desc As String
Dim v, lastrow As Long
' project number
srNo = ActiveSheet.Range("D2").Value
' find desc from CO_List sheet based on CO Number
Set wb = ActiveWorkbook
With wb.Sheets("CO_List")
lastrow = .Cells(.Rows.Count, "A").End(xlUp).Row
v = Application.Match(srNo, .Range("A3:A" & lastrow), 0)
If IsError(v) Then
MsgBox "No Description for '" & srNo & "'", vbExclamation
desc = "Description for " & srNo
Else
desc = Application.Index(.Range("B3:B" & lastrow), v)
End If
End With
' create new workbbok
Set wbNew = Workbooks.Add(1)
With wbNew.Sheets(1)
.Name = "Proj" & " " & srNo
.Range("A6:D6").Value = srNo
.Range("A16") = desc
End With
MsgBox "New workbook created for " & srNo, vbInformation
'wbNew.Save
End Sub