i am getting an out of memory error only when i try to add the name to this chart - excel

Question

i have a sub which will create a chart onto a sheet, when i try to add the name to the chart with .name it gives me an error "out of memory". i have tried to add it inside the with block but the same error and i also tried with different name instead of hi but still the same thing.
Option Explicit
Sub addchartv4()
Dim chart As chart
Dim xRg As Range
Dim chartdatarange As Range, chartExists As Boolean
Set chartdatarange = Worksheets("count_issue").Range("a3:c17")
' chartexists = False
' For Each Chart In ActiveSheet.ChartObjects
' If Chart.Name = "issue_count" Then
' chartexists = True
' Exit For
' End If
'
' Next Chart
'
Set chart = Nothing
On Error Resume Next
Set chart = Worksheets("chart11").ChartObjects
On Error GoTo 0
If chart Is Nothing Then
Set chart = Worksheets("chart11").ChartObjects.Add(Left:=Range("a1").Left, Top:=Range("a1").Top, Width:=400, Height:=300).chart
chart.Name = "hi"
With chart
.ChartType = xlColumnClustered
.SetSourceData Source:=chartdatarange
', PlotBy:=xlColumns
.SeriesCollection(1).XValues = chartdatarange.Columns(1)
.HasTitle = True
.ChartTitle.Text = "issue_count"
.HasLegend = False
.SetElement msoElementDataLabelOutSideEnd
.SetElement msoElementPrimaryCategoryGridLinesNone
.SetElement msoElementPrimaryValueAxisNone
End With
End If
End Sub

Answer 1

You shouldn't name the chart, but the chartObject.
The ChartObject is the container for the chart (and is part of the Shapes-collection of a worksheet. Inside the ChartObject you have the Chart-property which defines the real chart. You cannot name the chart, you can only name the ChartObject. The chart has automatic generated name (containing sheet + chartObject name). Trying to set the name manually leads to this "Out of Memory" error (which is just a symptom that something failed).
Now the fix is simple, but you have another issue in your code: When you check if the sheet contains already a chart(object), with the command Set chart = Worksheets("chart11").ChartObjects you try to assign a chartObjects-collection to a chart variable. This will fail in any case with a "Type mismatch". As you enclosed the command with On Error Resume Next, it will look as if there is never a chart on that worksheet and every time a new chart is created.
If you always have only one chart on the sheet, you could change the code to
' Check if there is already a chart on the sheet
If Worksheets("chart11").ChartObjects.Count > 0 then Exit Sub
Dim co as ChartObject
With Worksheets("chart11")
' Create a new Chart
Set co = .ChartObjects.Add(Left:=.Range("a1").Left, Top:=.Range("a1").Top, Width:=400, Height:=300)
co.Name = "hi"
Debug.Print co.Name, co.Chart.Name ' <-- You will see "Hi chart11 Hi"
End With
With co.Chart
...(Do your chart magic here)
End With
If you want to check if the chart "Hi" already exists, use
Dim co As ChartObject
On Error Resume Next
' Check if Chart "Hi" already exists
Set co = Worksheets("chart11").ChartObjects("Hi")
If Not co Is Nothing Then Exit Sub
On Error Resume Next