Accept documents using MsgBox - excel

Question

I have most of the workings down and functional, there is one thing however that I am struggling to get my head around. What essentially happens is a person opens the form on an Excel sheet, fills it out and submits to the sheet.
At the bottom of the form there is an option to upload 2 documents, each is using its own button to display the file explorer. One of the forms MQF094 is always required, the second MQF095 is only required sometimes. Whenever they add a document to the form, the name of that document is displayed in a text box so the user can check that they have attached the right document before submitting to the sheet.
What I am trying to do is when a person clicks 'Submit' on the form a message box appears asking them if MQF095 is required, if they click no then the info is posted to the sheet as normal, if they click yes then they are prompted to add a form using the file explorer.
Currently if a person only adds MQF094 it works fine, however if they add both an MQF094 and MQF095 form, they are both posted to the sheet but in name only, there is no link to the actual document. This link however works just if only posting MQF094
The code for this is below. I can post my full code is necessary:
Dim TargetRow As Integer
Dim answer As Integer
TargetRow = Sheets("Backend").Range("K3").Value + 1
If MQF095Text.Value = "" Then
answer = MsgBox("Does an MQF095 form need to be added?", vbQuestion + vbYesNo, "MQF095 Query")
End If
If answer = vbYes Then
Sheets("Software Evaluation").Hyperlinks.Add Anchor:=Sheets("Software Evaluation").Range("Software_Start").Offset(TargetRow, 6), Address:=stpPath _
, TextToDisplay:=MQF095Text.Value
Else: answer = vbNo
Sheets("Software Evaluation").Hyperlinks.Add Anchor:=Sheets("Software Evaluation").Range("Software_Start").Offset(TargetRow, 5), Address:=strPath _
, TextToDisplay:=MQF094Text.Value
With Sheets("Software Evaluation").Range("Software_Start")
.Offset(TargetRow, 1).Value = SoftwareNam
.Offset(TargetRow, 2).Value = SupplierName
.Offset(TargetRow, 3).Value = PrincipalApp
.Offset(TargetRow, 4).Value = TypeCombo
.Offset(TargetRow, 5).Value = MQF094Text
.Offset(TargetRow, 6).Value = MQF095Text
End With
End If
MsgBox "Software Entry Added Successfully", vbOKOnly, "Software Added"

Answer 1

Try if this is the correct logic
Private Sub CommandButton1_Click()
Dim TargetRow As Integer, answer As Integer
Dim ws As Worksheet, rng As Range
' test values
Const strPath = "C:\" ' MQF094 file
Const stpPath = "C:\" ' MQF095 file
Set ws = Sheets("Software Evaluation")
Set rng = ws.Range("Software_Start")
TargetRow = Sheets("Backend").Range("K3").Value + 1
If MQF095Text.Value = "" Then
answer = MsgBox("Does an MQF095 form need to be added?", vbQuestion + vbYesNo, "MQF095 Query")
End If
With rng
.Offset(TargetRow, 1).Value = SoftwareNam
.Offset(TargetRow, 2).Value = SupplierName
.Offset(TargetRow, 3).Value = PrincipalApp
.Offset(TargetRow, 4).Value = TypeCombo
ws.Hyperlinks.Add Anchor:=.Offset(TargetRow, 5), _
Address:=strPath, TextToDisplay:=MQF094Text.Value
If answer = vbYes Then
ws.Hyperlinks.Add Anchor:=.Offset(TargetRow, 6), _
Address:=stpPath, TextToDisplay:=""
Else
.Offset(TargetRow, 6).Value = MQF095Text.Value
End If
End With
MsgBox "Software Entry Added Successfully", vbOKOnly, "Software Added"
End Sub