How to merge a default list of Object with values from tfvars (Terraform) - terraform

Question

I'm trying to achieve something with Terraform and I getting some trouble to find any solution.
I define a variable like this:
variable "node_pools" {
type = list(object({
name = string
location = string
cluster = string
initial_node_count = number
tag = string
}))
default = [
{
name = "default-pool"
cluster = "cluster_name"
location = "usa"
initial_node_count = 3
tag = "default"
}]
}
Then, in my tfvar file, I define my node_pools like that:
node_pools = [
{
name = "pool-01"
tag = "first-pool"
},
{
name = "pool-highmemory"
tag = "high-memory"
}
]
Then, in my main.tf I try to use my node_pools variable but I need them filled with the default values which are not specified in the tfvar, like location, cluster, etc..
I think I need to merge, but I don't find any way to achieve that.
Thanks for any help.

Answer 1

The default value for a whole variable is only for situations where the variable isn't assigned any value at all.
If you want to specify default values for attributes within a nested object then you can use optional object type attributes and specify the default values inline inside the type constraint, like this:
variable "node_pools" {
type = list(object({
name = string
location = optional(string, "usa")
cluster = optional(string, "cluster_name")
initial_node_count = optional(number, 3)
tag = optional(string, "default")
}))
default = [
{
name = "default-pool"
},
]
}
Because these default values are defined directly for the nested attributes they apply separately to each element of the list of objects.
If the caller doesn't set a value for this variable at all then the single object in the default value will be expanded using the default values to produce this effective default value:
tolist([
{
name = "default-pool"
location = "usa"
cluster = "cluster_name"
initial_node_count = 3
tag = "default"
},
])
With the tfvars file you showed the effective value would instead be the following:
tolist([
{
name = "pool-01"
location = "usa"
cluster = "cluster_name"
initial_node_count = 3
tag = "first-pool"
},
{
name = "pool-highmemory"
location = "usa"
cluster = "cluster_name"
initial_node_count = 3
tag = "high-memory"
},
])