Trying to get all the values in a cell to display horizontally.
I can do index and match but whenever I try to put concat in, it doesn't work.
Related
=countif(E2:E21*E23:E37*I2:I20*I22:I37,VLOOKUP(C3, C2:C21*C23:C37*K2:K20*K22:K37,1,0))
I am trying to use the formula above to do the following: I need to calculate the sum of all non empty cells in the login columns on all the ranges in the sheet that have station type ARSAW. I know all of them are empty right now but I'm speaking of when they are not empty.
I need to list all column indexes of a table in Excel with a given value.
I use function MATCH but it only shows the first column they found.
Some people tell me use OFFSET inside the MATCH function but I don't know how to do it.
Example with picture is shown here. I want to write a formula which show result like MARK column:
example
If I understand you correctly based on your example this should work:
=TEXTJOIN(",",1,IF(B2:F2="x",$B$1:$F$1,""))
B2:F2 is range in same row with "x" in it
$B$1:$F$1 is the header row
Basically what it does is it will replace all headers that don't have "x" with blank values and join all headers without blank values together
I have a dummy data for origin and destination, I want to find list of cities as text which are 4 hrs. of destination. It should give me a list of cities when I change the origin. Can this be done easily by doing some lookup and match function?
The value to lookup is in A8, and this is matched to the first column:
=XMATCH(A8,A2:A6)
Then return this row from the numerical data using INDEX (A10):
=INDEX(B2:F6,A9,)
The last comma is needed to return the entire row.
FILTER this to return only the values greater than B8 (the criteria) (A11):
=FILTER(A10#,A10#>=B8)
Then multi-match using XLOOKUP (A12):
=XLOOKUP(A11#,A10#,B1:F1)
Put it all together using LET to save space (A14):
=LET(A,INDEX(B2:F6,A9,),XLOOKUP(FILTER(A,A>=B8),A,B1:F1))
I cannot figure out how to make the below formula work - it always results in an #N/A. I'm trying to search in a cell for certain text from a list and return when a match is found another text from a list.
!(https://photos.google.com/photo/AF1QipMrqey3My-qDeMlFSWoNmvyp39lo8H5Q8Fl_k4)
I tried vlookup, and want to avoid the usage of if (the complete list is about 40+ countries) but cannot make it work a index, search and isnumber.
My end result would be the following : search the cell "Singapore FSS", have the formula recognize "Singapore" and return the value of "ASE"
=INDEX(D1:E4,MATCH(TRUE,ISNUMBER(SEARCH(A2,D1:D4)),0),MATCH("text to return",D1:E1,0))
Thank you in advance for your help and comments
Ok, here's the logic:
We have cells to be processed and a table with cities/codes to be found and return
Build an array of indices of found cities using SEARCH function (this array will contain either index or #VALUE! if city isn't found)
Find the position of a non-error element (Ok, I consider, that there's only one match, so we return the first one) using MATCH function
Find the value to return using obtained relative position
Here's my sample data:
Here's the function. It should be array-formula to properly build array of indices (create it for the first cell using Ctrl-Shift-Enter)
{=INDEX($E$1:$E$4;MATCH(1;SEARCH($D$1:$D$4;A1);-1))}
Then simply drag it, or use Excel Tables.
The result:
I have a data set with range A4:S3365. My lookup value is A3 and I am trying to search or lookup the value in column E and return data on column A. however, multiple data in column A are assigned to the same lookup value in A3 and so when I do an index match function, it only returns the first value that it finds. It does not keep return other values in Column A that are also assigned to A3.
Can you help to fix this?
This is what I have tried so far:
INDEX(Tempxxl!$A$4:$A$3365,MATCH($A3,Tempxxl!$E$4:$E$3365,0))
When I run this code, I get the same value returned multiple times. I will like all the values in column A assigned to the lookup value in A3 to be listed out when i drag the formula down.
If you have the latest version of Excel including the function =TextJoin() then the following solution should work:
{=TEXTJOIN("|",TRUE,IF(Tempxxl!$E$4:$E$3365=$A3,Tempxxl!$A$4:$A$3365,""))}
Please note that this is an array formula and must be entered as such. That means that you should not enter the curved brackets but only everything inside the curved brackets and then press Ctrl + Shift + Enter. Excel will then add automatically the curved brackets.