Duplicate output rows - gnuplot

Question

I tried to plot this dataset, but got extra lines on the output.
Here is my dataset, feedings.data:
2023-01-22 09:00
2023-01-22 11:40
2023-01-22 13:30
2023-01-22 19:40
2023-01-22 22:15
2023-01-23 04:45
2023-01-23 07:45
2023-01-23 10:15
2023-01-23 12:30
2023-01-23 13:30
2023-01-23 17:45
2023-01-23 22:45
2023-01-24 02:45
2023-01-24 07:30
2023-01-24 10:30
2023-01-24 13:30
2023-01-24 17:45
Here is a simplified version of my gnuplot program:
reset
set output "./feedings.png"
set xdata time
set format x "%H:%M"
set ytics time;
set format y "%Y-%m-%d"
plot "./feedings.data" using (timecolumn(2, "%H:%M")):(timecolumn(1, "%Y-%m-%d")) with points;
Here is the output:
How can I get rid of the superfluous empty lines on the y axis?

Answer 1

Short answer:
set ytics 86400
unset mytics
Set the major ytic distance manually, i.e. 86400 seconds are one day.
If your y-range is more than just 2 or 3 days the gnuplot auto-tics should reduce the number of major tics automatically.
Remove the minor ytics via unset mytics.
I would use the newer syntax without set xdata time, but set format x "%H:%M" timedate and set format y "%Y-%m-%d" timedate.
Script:
### customize timedate format ytics
reset session
$Data <<EOD
2023-01-22 09:00
2023-01-22 11:40
2023-01-22 13:30
2023-01-22 19:40
2023-01-22 22:15
2023-01-23 04:45
2023-01-23 07:45
2023-01-23 10:15
2023-01-23 12:30
2023-01-23 13:30
2023-01-23 17:45
2023-01-23 22:45
2023-01-24 02:45
2023-01-24 07:30
2023-01-24 10:30
2023-01-24 13:30
2023-01-24 17:45
EOD
set format x "%H:%M" timedate
set format y "%Y-%m-%d" timedate
set offsets 0,0,0.5,0.5
set ytics 86400
unset mytics
plot $Data u (timecolumn(2, "%H:%M")):(timecolumn(1, "%Y-%m-%d")) \
w p pt 7 lc "red" ti "Data"
### end of script
Result: