VBA Split on column - multiple variables - excel

Question

I have a VBA code that splits my data into seperate worksheets, based on the variables in a chosen column.
This works great, however I have a few variables that I want in the same sheet, dispite having a different name.
Example:
In column B I have company A, B, C, D & E. These companies gets split into different worksheets.
However, company A & C has the same parent company, and therefore should be in the same worksheet.
How can i add this to my code, if I include a table like below in my file?
Column A
Column B
Company A
Group 'World'
Company B
Group 'Other'
Company C
Group 'World'
Company D
Group 'Other'
Company E
Group 'Other'
Sub Step1_split()
Dim lr As Long
Dim ws As Worksheet
Dim vcol, i As Integer
Dim icol As Long
Dim myarr As Variant
Dim title As String
Dim titlerow As Integer
'This macro splits data into multiple worksheets based on the variables on a column found in Excel.
'An InputBox asks you which columns you'd like to filter by, and it just creates these worksheets.
Application.ScreenUpdating = False
vcol = Application.InputBox(prompt:="Which column would you like to filter by?", title:="Filter column", Default:="2", Type:=1)
Set ws = ActiveSheet
lr = ws.Cells(ws.Rows.Count, vcol).End(xlUp).Row
title = "A1"
titlerow = ws.Range(title).Cells(1).Row
icol = ws.Columns.Count
ws.Cells(1, icol) = "Unique"
For i = 2 To lr
On Error Resume Next
If ws.Cells(i, vcol) <> "" And Application.WorksheetFunction.Match(ws.Cells(i, vcol), ws.Columns(icol), 0) = 0 Then
ws.Cells(ws.Rows.Count, icol).End(xlUp).Offset(1) = ws.Cells(i, vcol)
End If
Next
myarr = Application.WorksheetFunction.Transpose(ws.Columns(icol).SpecialCells(xlCellTypeConstants))
ws.Columns(icol).Clear
For i = 2 To UBound(myarr)
ws.Range(title).AutoFilter field:=vcol, Criteria1:=myarr(i) & ""
If Not Evaluate("=ISREF('" & myarr(i) & "'!A1)") Then
Sheets.Add(after:=Worksheets(Worksheets.Count)).Name = myarr(i) & ""
Else
Sheets(myarr(i) & "").Move after:=Worksheets(Worksheets.Count)
End If
ws.Range("A" & titlerow & ":A" & lr).EntireRow.Copy Sheets(myarr(i) & "").Range("A1")
'Sheets(myarr(i) & "").Columns.AutoFit
Next
ws.AutoFilterMode = False
ws.Activate
Application.ScreenUpdating = True
End Sub
I have tried adding an IF formula in the code, but have no idea how to do it.

Answer 1

Create a sheet named "Groups" for your table of relationships. Build an array of company names to use in the filter criteria.
Option Explicit
Sub Step1_split()
Dim wb As Workbook, wsGroups As Worksheet
Dim wsSrc As Worksheet, wsTarget As Worksheet
Dim rngFilter As Range, rngCopy As Range
Dim lastrow As Long, r As Long, grp As String
Dim i As Long, n As Long, arCrit, vcol
Set wb = ThisWorkbook
With wb
Set wsSrc = .Sheets(1) '.ActiveSheet
Set wsGroups = .Sheets("Groups") ' as req
End With
vcol = Application.InputBox( _
prompt:="Which column would you like to filter by ?", _
title:="Filter column", Default:="2", Type:=1)
If vcol = "False" Then Exit Sub ' cancel
' filter range
With wsSrc
lastrow = .Cells(.Rows.Count, vcol).End(xlUp).Row
Set rngFilter = .Cells(1, vcol).Resize(lastrow)
Set rngCopy = .Cells(1, 1).Resize(lastrow)
.AutoFilterMode = False
End With
' get parent-company details
Dim dict As Object, k
Set dict = CreateObject("Scripting.Dictionary")
With wsGroups
lastrow = .Cells(.Rows.Count, "A").End(xlUp).Row
For r = 2 To lastrow
grp = Trim(.Cells(r, "B"))
If Not dict.exists(grp) Then
dict.Add grp, New Collection
End If
dict(grp).Add Trim(.Cells(r, "A"))
Next
End With
' create sheet for each group, clear existing
Application.ScreenUpdating = False
i = wb.Sheets.Count
For Each k In dict.keys
grp = Replace(CStr(k), "'", "") ' take out single quotes
On Error Resume Next
Set wsTarget = wb.Sheets(grp)
On Error GoTo 0
If wsTarget Is Nothing Then
wb.Sheets.Add(after:=wb.Sheets(i)).Name = grp
i = i + 1
Set wsTarget = wb.Sheets(i)
Else
wsTarget.Cells.Clear
End If
' create aray
ReDim arCrit(0 To dict(k).Count - 1)
For n = 1 To dict(k).Count
arCrit(n - 1) = dict(k)(n)
Next
'Debug.Print k, Join(arCrit, ";")
' filter with array as criteria and copy
With rngFilter
.AutoFilter Field:=1, Criteria1:=arCrit, _
Operator:=xlFilterValues
rngCopy.Copy wsTarget.Range("A1")
End With
Set wsTarget = Nothing
Next
wsSrc.AutoFilterMode = False
Application.ScreenUpdating = True
MsgBox "Done"
End Sub