just trying to overcome that ranking problem and i stuck to find the solution for it.
Basically, i would like to rank on below based on Date filter on Cell C2.
But only want to start the ranking from cell A20 when it matches with the filtered Date.
Also increment identical values on "Prob" column by one
is there any way to do it please?
Use COUNTIFS with a relative reference:
=IF(AND($A6=$C$2,$B6<>""),COUNTIFS($A$6:$A6,$C$2,$B$6:$B6,"="&$B6)+COUNTIFS($A:$A,$C$2,$B:$B,">"&B6),"")
Related
I have a table like this (Sheet2):
Where im gonna be adding next columns in the future.
The thing i want to do is, create a small table with TOP 10 users (Sheet1), base on the criteria which is date in cell B2.
Like that:
I've manage to retrieve TOP 10 scores based on criteria (cell B2)
=LARGE(IF(branch_units!$C$2:$O$2=$B$2,branch_units!$C$3:$D$48),D3)
But i really can't match names with the score.
Is it possible? Can someone try to explain it to me with an example? Thank You all.
You can use INDEX/MATCH like below
=INDEX(Branch_units!$B$3:$B$8,MATCH(F3,Branch_units!$C$3:$C$8,0))
If you want to select columns dynamically based on date then use below formula.
=INDEX(Branch_units!$B$3:$B$8,MATCH(F3,INDEX(Branch_units!$C$3:$G$8,,MATCH($B$2,Branch_units!$C$2:$G$2,0)),0))
So, when you change date on B2 cell, your score column will change and still you will get name for that changes.
I'm hoping someone can help with a formula to input the value of Testing for June in cell A20 (FOR EXAMPLE).
So first criteria is the month as Jun-21 and then the next is the word testing.
I need more than a basic sum function as it needs to include the total purely based on the month and the name
If you need to lookup a value using both the row label and column label, using index/match is the formula to use. I assume you only have two different table, so this formula looks up the number in the first table, then looks up the value in the second table and adds them together.
=INDEX(J3:P8,MATCH(B12,J3:J8,0),MATCH(B13,J3:P3,0))+INDEX(A3:G8,MATCH(B12,A3:A8,0),MATCH(B13,A3:G3,0))
Thanks heaps for that!
How about if it were two tables but only some items are in each. So say if testing was only in one table but passing is in both - I hope to be able to use the same sum for all so is there something I can add in to the formula so it knows to just include the one total if it can't see the name testing in the other table?
Would it be somehow incorporating a lookup instead?
This is a two part question. I want to lookup a price of an item based upon the effective date of the price. I've seen the vertical effective date examples but mine is somewhat different. I have the Items in the first column (A). The remaining columns contain a header with the effective date of the price. Hopefully I'm able to attach the format example. The reason I have the table formatted this way is that I don't want to duplicate the items when a new price is entered. So, I want to provide the formula an ITEM and then select the current price base upon the effective date. Right now the table has 2 effective date columns. So,The second question is how can I format the table so when I add a NEW price with a new effective date (an additional column) without having to change the look-up formula? Can the formula be formatted to be dynamic?
Thanks in advance for your input.
As per my comment:
The formula in B11:
=INDEX(1:8,MATCH(A11,A:A,0),MATCH(TRUE,INDEX(ISBLANK(1:1),),0)-1)
As you notice I have populated A1 to get this working correctly.
You can use:
=INDEX(1:1040000,MATCH("ITEM1",A:A,0),MATCH(1E+99,1:1))
If the date is always equal to or less than today I would use:
=INDEX(1:1040000,MATCH("ITEM1",A:A,0),MATCH(TODAY(),1:1))
Where the item can be replaced with a cell reference that contains the item to be looked up.
Please refers to JvdV's table, another shorter formula option
In B11, enter formula :
=LOOKUP(9.9E+307,INDEX(1:8,MATCH(A11,A:A,0),0))
Thank you everyone for your input. It was invaluable for working a solution to my problem.
I'm trying to calculate the number of occurrences per day for several columns of data.
Here's an example of my data set:
Data set
Here's how I need to present it:
Present data
Any help is greatly appreciated!
In the Cell W3 of Sheet 2, use the COUNTIFS formula to achieve the desired result. You might need to change the sheet name in the below example or column names.
=COUNTIFS('Sheet1'!$B:$B,'Sheet2'!$A3,'Sheet1'!$A:$A,'Sheet2'!W$2)
and just drag this formula to the right and down and you'll get the desired results.
I'm trying to return a text value based on other text values matching AND a row's date falling in between another specified date range.
I'll try to create a simplified example of what I'm trying to achieve.
Let's say I have the following table breaking out produce units sold by day:
ProduceTable:
Now, let's say that I have another table detailing the discounts that I ran for items during certain date ranges:
ProducePromoTable:
[Edit: This example isn't great because the discount amounts are numerical, so ignore that and pretend that it's just text because that's what I'm really after. SUMIFS (I think) are off the table since I'm not trying to return a number value.]
What I would like to do is pull the discount amount into the first table based on whether the type of produce matches AND checking for whether there was a discounted price on that item on that particular day.
I've tried some lookup combinations and index-match, but I haven't quite cracked the code.
Anyone have any suggestions?
Assuming your other table is on a sheet named 'Discounts', then you can use this formula on cell D2 of the first table and copy down:
=IFERROR(INDEX(Discounts!$B$2:$B$6,MATCH(1,INDEX((Discounts!$A$2:$A$6=B2)*(Discounts!$C$2:$C$6<=A2)*(Discounts!$D$2:$D$6>=A2),),0)),"")
I would use the SUMPRODUCT function to find your values:
=IFERROR(INDEX($G$2:$G$5,SUMPRODUCT(($F$2:$F$5=B2)*($H$2:$H$5<=A2)*($I$2:$I$5>=A2)*ROW($G$2:$G$5))-1),"Not in Range")