VBA Dictionary Array - Multiple columns - excel

Question

I have basic understanding of VBA, so any help is appreciated. I want to count unique columns a, b, e, and remove the duplicates. columns c, d are to be summarized. The code I have now only works on the first 3 columns (code attached and before and after current macro via images). I am not sure how to add in the additional requirements. Thank you
Before Macro
After Current Macro
Sub LineSmasher()
Dim dict As Object, i As Long, dKey As String
Set dict = CreateObject("Scripting.Dictionary")
For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
dKey = (Cells(i, 1) & " " & Cells(i, 2))
dict(dKey) = Cells(i, 3) + dict(dKey)
Next i
Range(Range("A1"), Range("C" & Rows.Count).End(xlUp)).RemoveDuplicates Columns:=Array(1, 2)
For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
dKey = (Cells(i, 1) & " " & Cells(i, 2))
If Not Cells(i, 3) = dict(dKey) Then Cells(i, 3) = dict(dKey)
Next i
End Sub

Answer 1

Scan up the sheet, use the dictionary to reference the row where key first occurred. Summate the values and delete row.
Option Explicit
Sub LineSmasher()
Dim dict As Object, sKey As String
Dim ws As Worksheet, rngDel As Range
Dim i As Long, r As Long, n As Long, lastrow As Long
Set dict = CreateObject("Scripting.Dictionary")
Set ws = ThisWorkbook.Sheets("Sheet1")
With ws
lastrow = .Range("A" & .Rows.Count).End(xlUp).Row
For i = lastrow To 2 Step -1
sKey = .Cells(i, 1) & " " & .Cells(i, 2)
If dict.exists(sKey) Then
r = dict(sKey)
' summate
.Cells(r, "C") = .Cells(r, "C") + .Cells(i, "C")
' delete later
If rngDel Is Nothing Then
Set rngDel = .Rows(i)
Else
Set rngDel = Union(rngDel, .Rows(i))
End If
n = n + 1
Else
dict.Add sKey, i
End If
Next
End With
If rngDel Is Nothing Then
MsgBox "No lines deleted", vbExclamation
Else
rngDel.Interior.Color = vbRed
If MsgBox("Delete rows", vbYesNo) = vbYes Then
rngDel.Delete
MsgBox n & " lines deleted", vbInformation
End If
End If
End Sub