Search for a line containing characters, hyphen and numbers following hyphen with sed - search

Question

Let's suppose a file with following content named file.txt is used as a source.
12345
ABC-12
XCD-13
BCD-12345
Some text on this line
*+-%&
What I am looking for with sed would be to get only ABC-12 line and remove hyphen so the desired output would be ABC12
So far I have been able to get numbers only with following command:
sed "s/[^0-9]//g" file.txt
Output
12345
12
13
12345
I got the closest with grep with command:
grep -oP 'ABC-\b\d{2}\b' file.txt
Output
ABC-12
How should this be constructed with sed and also hyphen removed from the output?
Note also that numbers after ABC can be considered as changing like a variable so the idea would be to search for "ABC and numbers following it after hyphen" instead of searching for "ABC-12" directly.

Answer 1

idea would be to search for ABC and numbers following it after hyphen
You may use this sed for this:
sed '/^ABC-[0-9][0-9]$/!d; s/-//' file
ABC12
Here:
/^ABC-[0-9][0-9]$/!d: Searches input for a line that starts with ABC followed by a hyphen followed by 2 digits and end. All non-matching lines are removed due to !d as command.
s/-//p: Removes - from the match
Update:
As per comment below if ABC- text is not at the start then use:
sed -nE 's/.*(ABC)-([0-9][0-9]).*/\1\2/p' file

Answer 2

You can use
sed -En '/^.*(ABC)-([0-9]+).*/{s//\1\2/p;q}'
Details:
-En - E enables POSIX ERE and n suppresses default line output
^.*(ABC)-([0-9]+).* - start of string (here, line), then any text, then ABC captured into Group 1, -, then one or more digits (captured into Group 2) and then the rest of the line
{s//\1\2/p;q} - if there was a match
s//\1\2/p - take the same pattern and replace with Group 1 + Group 2 text, and print the result of the substitution
q - quit (you only need the first match here).
See the online demo:
#!/bin/bash
s='ABC-12
XCD-13
BCD-12345
Some text on this line
*+-%&'
sed -En '/^.*(ABC)-([0-9]+).*/{s//\1\2/p;q}' <<< "$s"
Output:
ABC12