Terraform - Azure Load Balancer Rule - Referencing frontend IP - azure

Question

Could you please help with pointing me in the right direction? I am unable to reference the name of my frontend ip configuration, from my load balancer resource, to my load balancer rule resource.
I have read the documentation and reference the front end ip configuration name in the load balancer rule via the exported front_ip_configuration name. In addition to also trying just copying the name of the public IP name in the load balancer rule resource.
Please see the below load-balancer.tf config file
resource "azurerm_public_ip" "internal_lb_public_ip" {
name = "PublicIPForLB"
location = data.azurerm_resource_group.rg.location
resource_group_name = data.azurerm_resource_group.rg.name
allocation_method = "Static"
sku = "Standard"
}
# internal standard sku load balancer
resource "azurerm_lb" "internal_lb" {
name = "myIntLoadBalancer"
location = data.azurerm_resource_group.rg.location
resource_group_name = data.azurerm_resource_group.rg.name
sku = "Standard"
frontend_ip_configuration {
name = "LoadBalancerFrontEndIP"
public_ip_address_id = azurerm_public_ip.internal_lb_public_ip.id
}
tags = local.common_tags
}
#-------------------------------------------------------------
# backend address pool - defines the group of resources that will serve traffic for a given load-balancing rule.
resource "azurerm_lb_backend_address_pool" "backend_pool" {
loadbalancer_id = azurerm_lb.internal_lb.id
name = "myBackendPool"
}
# addresses of vms placed within backend address pool.
# note: "backend Addresses can only be added to a Standard SKU Load Balancer."
resource "azurerm_lb_backend_address_pool_address" "backend_address" {
count = 3
name = "vmIP${count.index}"
backend_address_pool_id = azurerm_lb_backend_address_pool.backend_pool.id
# private ip address taken from virtual machine network interface asssociated with virtual machine
ip_address = azurerm_network_interface.vm_nic[count.index].private_ip_address
virtual_network_id = azurerm_virtual_network.lbvnet.id
}
#-------------------------------------------------------------
# health probe
resource "azurerm_lb_probe" "lb_http_health_probe" {
loadbalancer_id = azurerm_lb.internal_lb.id
name = "HTTPHealthProbe"
protocol = "Http"
port = 80
# URI, uniform resource identifier, used for requesting health status from the backend endpoint
request_path = "/"
# time gap between health probes
interval_in_seconds = 15
# number of failed probe attempts after which the backend endpoint is removed from rotation
number_of_probes = 2
}
#-------------------------------------------------------------
# laod balancing rule defining how traffic is distributed to the VMs
# azure load balancer resources require the Load Balancer needs to have a FrontEnd IP Configuration Attached
resource "azurerm_lb_rule" "lb_rule" {
loadbalancer_id = azurerm_lb.internal_lb.id
name = "myHTTPRule"
protocol = "Tcp"
frontend_port = 80
backend_port = 80
# name of the frontend IP configuration to which the rule is associated.
frontend_ip_configuration_name = "${azurerm_lb.internal_lb.frontend_ip_configuration[0].id}"
# idle timeout in minutes for TCP connections.
idle_timeout_in_minutes = 15
# reference to a Backend Address Pool over which this Load Balancing Rule operates.
backend_address_pool_ids = ["${azurerm_lb_backend_address_pool.backend_pool.id}"]
# a "floating” IP is reassigned to a secondary server in case the primary server fails
enable_floating_ip = false
# the load balancing distribution type to be used by the Load Balancer
load_distribution = "None"
}
#-------------------------------------------------------------
Please see the below debug outpt:
│ Error: expanding Load Balancer Rule: [ERROR] Cannot find FrontEnd IP Configuration with the name /subscriptions/00000000-00000-00000-0000-0000000000/resourceGroups/-----/providers/Microsoft.Network/loadBalancers/myIntLoadBalancer/frontendIPConfigurations/LoadBalancerFrontEndIP
│
│ with azurerm_lb_rule.lb_rule,│ on load-balancer.tf line 63, in resource "azurerm_lb_rule" "lb_rule":
│ 63: resource "azurerm_lb_rule" "lb_rule" {

Answer 1

Use this instead
frontend_ip_configuration_name = azurerm_lb.internal_lb.frontend_ip_configuration[0].name