multiplot of isolines and points creates two axis frames - gnuplot

Question

I've created a multiplot containing an isoline plot f(x,y) and a point, (0,0) on the zero level set of the isoline plot. Unfortunately the point plot appears to create a second axis frames as shown below
f(x,y)=2*x**2 - x + 2*y**2 - y - 2
set multiplot
set xrange [-3:3]
set yrange [-3:3]
set isosamples 250
set contour
unset surface
set view map
set key out
set cntrparam levels incremental 0,1,5
splot f(x,y)
plot "< echo '1 1'"
set nomultiplot
What can I do to solve this problem?
Update
A bit more context. In the larger problem I am using multiplot to superimpose two isoline plots, as hinted below. Both isoline plots share a common axis frame.
...
set cntrparam levels incremental 0,1,5
splot f(x,y)
set cntrparam levels discrete 0
g(x,y)=(x - 1)**2 + y**2 - 1
splot g(x,y)

Answer 1

Unless there are additional requirements that mandate use of multiplot, the simplest solution is to draw your single point as a label instead. The label comes with a point for free. You only want the point, so the label text is an empty string.
If this was a proxy question for a more complicated requirement, please edit the question to give more detail.
f(x,y)=2*x**2 - x + 2*y**2 - y - 2
set label 1 "" at 1,1,0 point pt 7 lc "blue"
set xrange [-3:3]
set yrange [-3:3]
set isosamples 250
set contour
unset surface
set view map
set key out
set cntrparam levels incremental 0,1,5
splot f(x,y) with lines
Edit
The multiplot version:
f(x,y)=2*x**2 - x + 2*y**2 - y - 2
g(x,y)=(x - 1)**2 + y**2 - 1
set label 1 "" at 1,1,0 point pt 7 lc "blue"
set xrange [-3:3]
set yrange [-3:3]
set isosamples 250
set contour
unset surface
set view map
set multiplot
set cntrparam levels incremental 0,1,5
set key out top
splot f(x,y) with lines
set cntrparam levels discrete 0
set key out bottom
splot g(x,y) with lines
unset multiplot

Answer 2

This would be my suggestion:
you don't need multiplot (I would use it only if absolute necessary)
plot the contour data into a table and instead of 3D splot and "set view map" use a 2D plot. Because after set contour you cannot plot a single datapoint as non-grid data.
there are a lot of ways to plot a single data point. My preference would be without system call.
you might want to set size ratio -1, then a circle appears as a circle
Update:
Here is the extended example after you mentioned your second contour function g(x,y).
Just to mention the differences between a multiplot solution and a single plot solution:
Script (multiplot): (with fixed margins and legend box positions relative to screen)
easy handling of the legend entries and boxes (but manual positioning if more than 2)
you need to set fixed margins to get reliable overlap independent of the legend. At least, fixed top/bottom margins are enough if you set size ratio -1. Additionally, you can set the legend to a fixed position relative to the screen.
I recommended to unset border, tics and labels for the second plot, otherwise these elements get a slight "bold" appearance if you plot them several times on top of each other (you will notice if you compare the numbers on Ethan's first and second plot)
zooming is not possible with multiplot in interactive terminals, e.g. wxt, qt
requires another multiplot if you want to plot single/multiple points from another file/datablock
so far, I haven't found out how to freely control the color of the contour lines. But I'm sure there is a way.
### plot several contour plots and add a single point (multiplot)
reset session
f(x,y) = 2*x**2 - x + 2*y**2 - y - 2
g(x,y) = (x-1)**2 + y**2 - 1
set xlabel "x-label"
set xrange [-3:3]
set ylabel "y-label"
set yrange [-3:3]
set samples 100
set isosamples 100
set contour
unset surface
set view map
set size ratio -1
set multiplot
xPos = 0.95
set key at screen xPos,0.9 title "Main title" font ",12"
set bmargin screen 0.15
set tmargin screen 0.92
set cntrparam levels incremental 0,1,5
splot f(x,y) w l
set cntrparam levels discrete 0
unset border
unset tics
unset xlabel
unset ylabel
set key at screen xPos,0.5 notitle
splot g(x,y) w l
set key at screen xPos,0.35 notitle
plot '+' u (1):(1) every ::::0 w p pt 7 lc "red" ti "You are here"
unset multiplot
### end of script
Result:
Script (single plot):
zooming possible in interactive terminals, e.g. wxt, qt
extra tables for contours
a bit more effort with the legend (but auto positioning)
easy customization of contour line color
For the single plot, the extraction of the contour level labels is a bit tricky and needs some explanations.
The contour data in the datablocks looks like this:
# Surface 0 of 1 surfaces
# Curve title: "f(x,y)"
# Contour 0, label: 5
-1 -1.15789 5
-1.15789 -1 5
-1.54386 -0.333333 5
...
-0.333333 -1.54386 5
-1 -1.15789 5
# Contour 1, label: 4
-0.333333 -1.38596 4
...
The data is separated by two empty lines. So, you can address the subblocks by using index (check help index).
So, now, after skipping the first 5 lines, you need to extract the contour label value from each the first line (header) of each (sub)block from the 5th column. For this, you need to tell gnuplot that # is not a comment character anymore (check help datafile commentschars).
Furthermore, the legend entry for the functions names are realized by keyentries (check help keyentry) with a fully transparent point according to the color scheme 0xaarrggbb where alpha is `0xff´.
### plot several contour plots and add a single point (single plot)
reset session
f(x,y) = 2*x**2 - x + 2*y**2 - y - 2
g(x,y) = (x-1)**2 + y**2 - 1
set xlabel "x-label"
set xrange [-3:3]
set ylabel "y-label"
set yrange [-3:3]
set samples 100
set isosamples 100
set contour
unset surface
set table $ContourF
set cntrparam levels incremental 0,1,5
splot f(x,y)
set table $ContourG
set cntrparam levels discrete 0
splot g(x,y)
unset table
set size ratio -1
set key noautotitle left at graph 1.05,1 title "Main title" font ",12"
set datafile commentschar ''
plot keyentry w p lc rgb 0xff123456 ti "f(x,y)", \
for [i=0:*] $ContourF u 1:2:3 skip 5 index i w l lc i ti columnhead(5), \
keyentry w p lc rgb 0xff123456 ti "g(x,y)", \
for [i=0:*] $ContourG u 1:2:3 skip 5 index i w l lc "blue" ti columnhead(5), \
'+' u (1):(1) every ::::0 w p pt 7 lc "red" ti "You are here"
### end of script
Result: