Copy Worksheets From One Workbook into Another - excel

Question

I would like to copy all the sheets from one workbook other than the first sheet to another workbook and then once the sheets have been copied to the other workbook, close it. Here is what I have for my code so far. Right now, it is copying all the sheets from Workbook SD09_KW.xlsm and pasting them into the Workbook Pending SD09 which is the correct location. However, I would like it to copy all the worksheets in SD09_KW other than the first sheet. It also is making copies of all the sheets in Pending SD09 and saving them inside the workbook too which I do not want it to do. Any help would be great! Thanks.
Sub CopySD()
Dim DataWorkbook As Workbook, PendingWorkbook As Workbook, Sheet As Worksheet
Set DataWorkbook = Workbooks.Open("C:\Users\Documents\SD09_KW.xlsm")
Set PendingWorkbook = Workbooks("Pending SD09")
For Each Sheet In DataWorkbook.Sheets
Sheets.copy After:=PendingWorkbook.Sheets(PendingWorkbook.Worksheets.Count)
Next
PendingWorkbook.Close SaveChanges:=True
End Sub
UPDATE: I have made a few changes, however, nwo I am getting an error of "Object doesn't support this property or method" in line DataWorkbook(i).Sheets.copy After:=PendingWorkbook.Sheets(PendingWorkbook.Worksheets.Count)
Here is the updated code:
Sub CopySD(sysnum As String) ' copies over the SD tabs created into the pending doc workbook
Dim DataWorkbook As Workbook, PendingWorkbook As Workbook, i As Long
Set DataWorkbook = Workbooks.Open("C:\Users\Documents\SD093_KW.xlsm")
Set PendingWorkbook = Workbooks.Open("C:\Users\Documents\Pending SD093.xlsx")
For i = 2 To DataWorkbook.Worksheets.Count
If Not SheetExists(sysnum, PendingWorkbook) Then ' SD tab not already saved to pending workbook
DataWorkbook.Sheets(i).copy After:=PendingWorkbook.Sheets(PendingWorkbook.Worksheets.Count) ' save SD tab to pending workbook
End If
Next
PendingWorkbook.Close SaveChanges:=True
Application.DisplayAlerts = False
For i = DataWorkbook.Sheets.Count To 2 Step -1
DataWorkbook.Sheets(i).Delete
Next i
Application.DisplayAlerts = True
End Sub

Answer 1

Copy/Delete Worksheets
Note the mistakes in your codes where you have used:
Sheets.Copy... instead of
Sheet.Copy...
DataWorkbook(i).Sheets.copy... instead of
DataWorkbook.Worksheets(i).Copy...
Note the inaccuracies (inconsistencies, mistakes if the workbooks contain charts) in your codes where you have used:
... In DataWorkbook.Sheets instead of
... In DataWorkbook.Worksheets
... After:=PendingWorkbook.Sheets(PendingWorkbook.Worksheets.Count) instead of
... After:=PendingWorkbook.Sheets(PendingWorkbook.Sheets.Count)
... To DataWorkbook.Sheets.Count instead of
... To DataWorkbook.Worksheets.Count
Copy All But the First Worksheet
For Each...Next
Sub CopyForEach()
Dim DataWorkbook As Workbook
Set DataWorkbook = Workbooks.Open("C:\Users\Documents\SD09_KW.xlsm")
Dim PendingWorkbook As Workbook
Set PendingWorkbook = Workbooks.Open("C:\Users\Documents\Pending SD09.xlsx")
Dim ws As Worksheet
Dim FoundFirst As Boolean
For Each ws In DataWorkbook.Worksheets
If FoundFirst Then
ws.Copy After:=PendingWorkbook.Sheets(PendingWorkbook.Sheets.Count)
Else ' skip first
FoundFirst = True
End If
Next ws
PendingWorkbook.Close SaveChanges:=True
End Sub
For...Next
Sub CopyForNext()
Dim DataWorkbook As Workbook
Set DataWorkbook = Workbooks.Open("C:\Users\Documents\SD09_KW.xlsm")
Dim PendingWorkbook As Workbook
Set PendingWorkbook = Workbooks.Open("C:\Users\Documents\Pending SD09.xlsx")
Dim i As Long
For i = 2 To DataWorkbook.Worksheets.Count ' 2 means skip first
DataWorkbook.Worksheets(i).Copy _
After:=PendingWorkbook.Sheets(PendingWorkbook.Sheets.Count)
Next i
PendingWorkbook.Close SaveChanges:=True
End Sub
Delete All But the First Worksheet
After PendingWorkbook.Close SaveChanges:=True you will use either
DeleteAllButFirstWorksheetForEachNext DataWorkbook
or
DeleteAllButFirstWorksheetForNext DataWorkbook
Of course, use shorter names for the procedures e.g. DeleteAllButFirst.
For Each...Next
Sub DeleteAllButFirstWorksheetForEachNext(ByVal wb As Workbook)
Dim wsCount As Long: wsCount = wb.Worksheets.Count
If wsCount < 2 Then Exit Sub
Dim WorksheetNames() As String: ReDim WorksheetNames(1 To wsCount - 1)
Dim ws As Worksheet
Dim n As Long
Dim FoundFirst As Boolean
For Each ws In wb.Worksheets
If FoundFirst Then
n = n + 1
WorksheetNames(n) = ws.Name
Else ' skip first
FoundFirst = True
End If
Next ws
Application.DisplayAlerts = False
wb.Worksheets(WorksheetNames).Delete
Application.DisplayAlerts = True
End Sub
For...Next
Sub DeleteAllButFirstWorksheetForNext(ByVal wb As Workbook)
Dim wsCount As Long: wsCount = wb.Worksheets.Count
If wsCount < 2 Then Exit Sub
Dim WorksheetNames() As String: ReDim WorksheetNames(1 To wsCount - 1)
Dim i As Long
Dim n As Long
For i = 2 To wsCount
WorksheetNames(i - 1) = wb.Worksheets(i).Name
Next i
Application.DisplayAlerts = False
wb.Worksheets(WorksheetNames).Delete
Application.DisplayAlerts = True
End Sub