How to rank multiple columns on excel. I'm using Microsoft Office Professional Plus 2016 [closed] - excel

Question

Closed. This question needs details or clarity. It is not currently accepting answers.
Want to improve this question? Add details and clarify the problem by editing this post.
Closed 5 months ago.
Improve this question
I have the following input data:
Contamination
10%
10%
20%
20%
30%
30%
Estimator
Trial 1
Trial 2
Trial 1
Trial 2
Trial 1
Trial 2
OLA
500
75
100
430
460
230
PWA
360
457
400
200
200
400
CA
470
270
450
250
350
150
HA
215
310
200
400
400
200
AM
300
500
315
200
500
250
Table has 5 different estimators each having 2 repeated trials for each of the 3 groups of percentages of contaminations (10%, 20%, and 30%) considered.
For each of the 5 estimators (in my real problem I have more than 5), I want to rank (from lower to highest value) among the trials within each group of percentages (in my real problem I have more than 3) simultaneously.
I am looking for a solution, that doesn't require manually to rank each group, since in my real problem I have a larger group of percentages, trials per group and experiments. The number of trials within each group are the same.
I want to get a formula that can rank it simultaneously. Here is the expected output from the input data sample:
Contamination
10%
10%
20%
20%
30%
30%
Estimator
Trial 1
Trial 2
Trial 1
Trial 2
Trial 1
Trial 2
OLA
2
1
1
2
2
1
PWA
1
2
2
1
1
2
CA
2
1
2
1
2
1
HA
1
2
1
2
2
1
AM
1
2
2
1
2
1
Notes:
I have an older version of Excel: Microsoft Office Professional Plus 2016, please consider that in your answer
The Contamination is the same within the trial set (Trial 1, Trial 2). Table Markdown feature doesn't allow to merge cells, that is why the percentage is repeated

Answer 1

I assume from your question:
I do not want to rank them individually as it will take much time
since I have more than 50 of them to rank
You are referring to the percentage groups and/or number of trials that can be large, which is the most difficult task to expand.
In the cell L3(see screenshot below) I put the first formula that can be expanded vertically and horizontally. Please pay attention to the $ mark to ensure it works in both directions.
=RANK(OFFSET($C3,0, L$2*$J$2 + L$1),
OFFSET($C3,0, L$2*$J$2,1,$J$2),1)
Using named ranges, for example naming $J$2 as totalTrials it is easier to understand the formula:
=RANK(OFFSET($C3,0, L$2*$totalTrials + L$1),
OFFSET($C3,0, L$2*totalTrials,1,totalTrials),1)
or even better, using the modern LET function to define all the variables first, is the easiest way to read it:
=LET(startCell,$C3, totalTrials,$J$2,
groupCnt, L$2*totalTrials, trialCnt,L$1,
RANK(OFFSET(startCell,0, groupCnt + trialCnt),
OFFSET(startCell,0, groupCnt,1,totalTrials),1)
)
and here is the output:
Changing the values of Trial per Group (J2) or # Groups (J4) and expanding the formula horizontally and vertically you can consider a large number of trials within the group, large number of groups and a large number of experiments.
Explanation
For doing the ranking per experiment within the group I use the RANK(number,ref,order). For jumping from one group to another and getting the specific trial within the group, the OFFSET(reference, rows, cols, height, width) function. (check this link for more information about OFFSET function).
For building the recurrence in the formula I use the following two helper rows:
L1:Q1: The trial number within the group, starting from zero, via the following formula: MOD((COLUMNS($A$1:A1)-1),$J$2). It generates the sequence: 0,1,2,...N, 0,1,2,..N, where N is the number of trials minus one (easier to start from zero for the recurrence). In the sample the number of trials is indicated in the cell: J2.
L2:Q2: The group number, starting from zero, that each trial belongs to via the following formula: INT((COLUMNS($A$1:A1)-1)/($J$2)). It generates the sequence: 0,0,0,..0, 1,1,1,..1,...M,M,M...M, where each number is repeated as many times as trials we have where M is the number of groups minus one.
Note: There is a more concise way for building such sequences in modern excel versions via SEQUENCE but you indicated you have an older version.
In order to generate both sequences, I took the idea from here: Excel Magic Trick 692: More About Incrementing Numbers In Formulas (that works for older excel versions)
Combining properly both helper rows in OFFSET, the rank is calculated per trial per experiment.
This explanatory picture from ExcelJet, helps to understand each input argument of the OFFSET function: