Transpose with default headers in excel - excel

Question

I have a simple data which is
Name Age
Venky 20
Anil 22
Output should be like :
Name : Venky
Age : 20
Name : Anil
Age : 22
Note : For each record should have header values
I have tried multiple ways apart from Macros
Can you please give me you inputs?

Answer 1

Without more specific context from the question, we can combine BYROW, MAP, TOCOL, TEXTJOIN, TEXTSPLIT and SUBSTITUTE to get the expected result (adding the link since some of them are relatively new Excel functions):
=LET(y,SUBSTITUTE(TEXTJOIN(";",,
BYROW(A2:C4, LAMBDA(x, TEXTJOIN(";",,MAP(TOCOL(A1:C1), TOCOL(x),
LAMBDA(a,b, a & ":"& b & ";")))))), ";;",";"),
TEXTSPLIT(LEFT(y, LEN(y) - 1),,";"))
The main idea is create on the fly for each row of input data(A1:B3 including the headers) a new array via MAP with the following structure (let’s call it tempArray:
| Name:name1; |
|-------------|
| Age:age1; |
Note: It works for more than two columns in the header, if that is the case a row per header item will be created.
For example:
=MAP(TOCOL(A1:B1), TOCOL(A2:B2), LAMBDA(a,b, a & ":"& b & ";"))
For the first row of the input data will return:
| Name:Venky; |
| ------------|
| Age:10; |
Then convert tempArray into a text via: TEXTJOIN so every element of BYROW, i.e. x is converted to a string, where each record is delimited by ;. For the first row it will be:
Name:Venky;;Age:10;
SUBSTITUTE is used to remove the extra ; generated by TEXTJOIN. For example for the first row it would be:
Name:Venky;Age:10;
After executing SUBSTITUTE the intermediate result would be:
Name:Venky;Age:20;Name:Anil;Age:22;
We use LEFT to remove the extra ; at the end. Now we have a string that has each row delimited by ;, so the string is ready to be converted back to an array using TEXTSPLIT.
Sample adding an additional record and Last Name as a new header item: