Populating UserForm Data to an Excel Table - excel

Question

I have created a UserForm as shown by the image. The data from this has to be populated to an excel table named 'Database'. I have copied various VBA Codes from the internet to populate the table but all in vain. The code is as follows:
Sub ResetItem() ' The reset button coding
Sub Submit_Data()
Dim iRow As Long
If adminpanel.txtRowNumber.Value = "" Then
iRow = student.Range("A" & Rows.Count).End(xlUp).Row + 1
Else
iRow = adminpanel.txtRowNumber.Value
End If
With student.Range("A" & iRow)
.Offset(0, 0).Value = "=Row()-1"
.Offset(0, 1).Value = UserForm1.Doc_number.Value
.Offset(0, 2).Value = UserForm1.DocDate.Value
.Offset(0, 3).Value = UserForm1.Order_Number.Value
.Offset(0, 4).Value = UserForm1.Fleet_number.Value
.Offset(0, 5).Value = UserForm1.Maitenance_Type.Value
.Offset(0, 6).Value = UserForm1.ROF.Value
.Offset(0, 7).Value = UserForm1.System_Type.Value
.Offset(0, 8).Value = UserForm1.Asy_Type.Value
.Offset(0, 9).Value = UserForm1.Comments.Value
.Offset(0, 10).Value = UserForm1.OEM.Value
.Offset(0, 11).Value = UserForm1.Part_Number.Value
.Offset(0, 12).Value = UserForm1.SAP_Code.Value
.Offset(0, 13).Value = UserForm1.Unit.Value
.Offset(0, 14).Value = UserForm1.Start_Time.Value
.Offset(0, 15).Value = UserForm1.Finish_Time.Value
.Offset(0, 16).Value = UserForm1.Tech01.Value
.Offset(0, 17).Value = UserForm1.Tech02.Value
.Offset(0, 18).Value = UserForm1.Tech03.Value
.Offset(0, 19).Value = UserForm1.Distance.Value
End With
Call Reset_Form
Application.ScreenUpdating = True
MsgBox "Done"
End With
End Sub

Answer 1

Following code assumes that student is a name of a worksheet.
Sub Submit_Data()
Dim student As Worksheet
Dim iRow As Long
Set student = ThisWorkbook.Worksheets("student") 'assuming sheet name is student
If IsNumeric(adminpanel.txtRowNumber.Value) Then
iRow = CLng(adminpanel.txtRowNumber.Value)
Else
iRow = student.Cells(student.Rows.Count, "A").End(xlUp).Row + 1
End If
With UserForm1
student.Cells(iRow, 1).Formula = "=ROW() - 1"
student.Cells(iRow, 2).Resize(1, 19).Value2 = Array( _
.Doc_number.Value, _
.DocDate.Value, _
.Order_Number.Value, _
.Fleet_number.Value, _
.Maitenance_Type.Value, _
.ROF.Value, _
.System_Type.Value, _
.Asy_Type.Value, _
.Comments.Value, _
.OEM.Value, _
.Part_Number.Value, _
.SAP_Code.Value, _
.Unit.Value, _
.Start_Time.Value, _
.Finish_Time.Value, _
.Tech01.Value, _
.Tech02.Value, _
.Tech03.Value, _
.Distance.Value _
)
End With
Call Reset_Form
'Application.ScreenUpdating = True no need for it
MsgBox "Done"
Set student = Nothing
End Sub