How can I only show differences to first value as GNUPlot dataline? - gnuplot

Question

I'm Using GNUPlot to show a graph for some measuring points. ( ~ 18.500 points)
The source looks like:
Date/time | Name | Value
21.07.2022 17:00:16 | M.01 - | 4045
21.07.2022 17:00:25 | M.02 - | 1789
21.07.2022 17:00:35 | M.03 - | 3245
21.07.2022 17:04:15 | M.01 - | 4043
21.07.2022 17:05:01 | M.02 - | 1793
21.07.2022 17:05:14 | M.03 - | 3246
21.07.2022 17:09:45 | M.01 - | 4042
21.07.2022 17:10:05 | M.02 - | 1793
21.07.2022 17:10:29 | M.03 - | 3247
I'm using the folowing script:
set datafile separator ';'
set xdata time
set xlabel "Zeit"
set ylabel "Abweichung"
set timefmt "%d-%m-%Y %H:%M:%S"
plot 'D:\_Local\gnuplot\source.csv' using 1:(stringcolumn(2) eq "M.01 -"? $3:1/0) title "M.01" lc rgb "blue" , "" using 1:(stringcolumn(2) eq "M.02 -"? $3:1/0) title "M.02" lc rgb "red", "" using 1:(stringcolumn(2) eq "M.03 -"? $3:1/0) title "M.03" lc rgb "green"
This works really fine and does the job really fine.
Now I want hot have a graph, which shows me the difference from the first given value
M.01 - | -2 | -1
M.02 - | 4 | 0
M.03 - | 1 | 1
I wasn't able to find some useful examples during my google searches, so I hope someone here is able to help me for this data correlation.

Answer 1

Assumption is that M.01, M.02 and M.03 are strictly repeating in this order. Then you can use every, check help every. If not, it will get a bit more complicated but feasible as well.
if you keep the standard column separator whitespace your values are in the 7th column.
when the first row number index (pseudocolumn 0, check help pseudocolumns) is equal to 0 then memorize this value in y0 and subtract it from the current and future values. every 3::1 means every 3rd value starting from index 1 (i.e. the 2nd row).
do this in a loop from 1 to 3
read your color from a string with hexadecimal numbers 0xrrggbb, i.e. 0xff000=red, 0x00ff00=green and 0x0000ff=blue. Check help colorspec.
Script:
### normalize several values to first values
reset session
$Data <<EOD
Date/time | Name | Value
21.07.2022 17:00:16 | M.01 - | 4045
21.07.2022 17:00:25 | M.02 - | 1789
21.07.2022 17:00:35 | M.03 - | 3245
21.07.2022 17:04:15 | M.01 - | 4043
21.07.2022 17:05:01 | M.02 - | 1793
21.07.2022 17:05:14 | M.03 - | 3246
21.07.2022 17:09:45 | M.01 - | 4042
21.07.2022 17:10:05 | M.02 - | 1793
21.07.2022 17:10:29 | M.03 - | 3247
EOD
myColor(i) = int(word("0x0000ff 0xff0000 0x00ff00",i))
myTimeFmt = "%d.%m.%Y %H:%M:%S"
set format x "%H:%M" timedate
set offsets 1,1,1,1
set grid x,y
set key top left
plot for [i=1:3] $Data u (timecolumn(1,myTimeFmt)):($0==0?y0=$7:0,$7-y0) every 3::i \
w lp pt 7 lc rgb myColor(i) title sprintf("M.%02d",i)
### end of script
Addition:
If you can't be sure that the sequence 1,2,3 is strictly followed, you can slightly modify the script. With this, it should work in any case and any order. Note the the filter function myFilter() and the additional line set datafile missing NaN.
Script: (note the irregular order of M.01, M.02 and M.03.)
### normalize several values to first values
reset session
$Data <<EOD
Date/time | Name | Value
21.07.2022 17:00:25 | M.02 - | 1789
21.07.2022 17:00:35 | M.03 - | 3245
21.07.2022 17:00:16 | M.01 - | 4045
21.07.2022 17:04:15 | M.01 - | 4043
21.07.2022 17:05:14 | M.03 - | 3246
21.07.2022 17:05:01 | M.02 - | 1793
21.07.2022 17:10:29 | M.03 - | 3247
21.07.2022 17:10:05 | M.02 - | 1793
21.07.2022 17:09:45 | M.01 - | 4042
EOD
myColor(i) = int(word("0x0000ff 0xff0000 0x00ff00",i))
myTimeFmt = "%d.%m.%Y %H:%M:%S"
set format x "%H:%M" timedate
set offsets 1,1,1,1
set grid x,y
set key top left
set datafile missing NaN
myFilter(col,v) = strcol(col) eq sprintf("M.%02d",v) ? (c=c+1, c==1?y0=$7:0, $7-y0): NaN
plot for [i=1:3] c=0 $Data u (timecolumn(1,myTimeFmt)):(myFilter(4,i)) \
w lp pt 7 lc rgb myColor(i) title sprintf("M.%02d",i)
### end of script
Result: (identical for both scripts)