How to see who viewed my shared excel sheet - excel

Question

I want to have a shared excel document, I want to know how many users have viewed it, basically its viewing history. I have checked for google sheets but that feature is only available for people with company domains not for individual. If anything apart from google sheet that can track the viewing history will also do. Please suggest

Answer 1

In the Workbook.Open event, make a call to this Sub. The user name, machine name and what time the user opened the file will be part of the filename. You can save more information when the code opens the file (see the code comment when printing to file):
Sub fnSaveAccessLog()
Dim strLogFile As String
Dim lngFF As Long
Dim strMachine As String
Dim strUser As String
Dim strDate As String
Dim strFileName As String
On Error Resume Next
MkDir ThisWorkbook.Path & "\Logs"
On Error GoTo 0
strLogFile = "UserAccess"
strMachine = Environ("computername")
strUser = Environ("username")
strDate = Year(Now) & Format(Month(Now), "00") & Format(Day(Now()), "00") & "_" & _
Format(Hour(Now()), "00") & Format(Minute(Now()), "00") & Format(Second(Now()), "00")
strFileName = ThisWorkbook.Path & "\Logs\" & strLogFile & "_" _
& strDate & "_" & strUser & "_" & strMachine & ".txt"
lngFF = VBA.FreeFile
Open strFileName For Output As #lngFF
Print #lngFF, "put more info here if desired"
Close #lngFF
End Sub
After reading #indnwkybrd's comments I modified the code, to implement the two commented suggestions (thanks!) and simplified the construction of the filename variable.
Option Explicit
Sub fnAppendAccessLog()
Dim lngFF As Long
Dim strMachine As String
Dim strUser As String
Dim strDate As String
Dim strFileName As String
On Error Resume Next
MkDir ThisWorkbook.Path & "\Logs"
On Error GoTo 0
strMachine = Environ("computername")
strUser = Environ("username")
strDate = Format$(Now, "yyyyMMDD_hhmmss")
strFileName = ThisWorkbook.Path & "\Logs\" & "UsersAccessLog - " & Split(ThisWorkbook.Name, ".")(0) & ".txt"
lngFF = VBA.FreeFile
Open strFileName For Append As #lngFF
Print #lngFF, Join$(Array(strUser, strMachine, strDate), vbTab)
Close #lngFF
End Sub