Issue With Event For A Textbox Class - excel

Question

I have created a textbox class for a form.
When the textbox classes are on a form, the events work fine. However, when I place the textbox classes on a multipage, the events no longer work
(Separately, I understand that OnEnter, OnExit, BeforeUpdate and AfterUpdate events are not present in VBA (as in VB), however I have some code that I references external libraries that allows these 'events' to work).
I have extracts of the code below. Perhaps some kind soul might see what the problem is.
clsBusinessCaseTextBoxEvents:
Public WithEvents objTextBox As MSForms.TextBox
Private objParent As clsBusinessCaseEventControl
'------------------------------------------
'Initialize
'------------------------------------------
Public Sub Initialize(Parent As clsBusinessCaseEventControl)
Set Me.Parent = Parent
With Parent.UserForm.Controls
'Set objTextBox = .Add("Forms.TextBox.1")
End With
End Sub
'------------------------------------------
'Parent Property
'------------------------------------------
Public Property Set Parent(sglValue As clsBusinessCaseEventControl)
Set objParent = sglValue
End Property
Public Property Get Parent() As clsBusinessCaseEventControl
Set Parent = objParent
End Property
clsBusinessCaseEventControl
Private colCollection As Collection
Private objUserForm As UserForm
Public Event Change(objTextBox As clsBusinessCaseTextBoxEvents)
Public Event AfterUpdate(objTextBox As clsBusinessCaseTextBoxEvents)
Public Event Enter(objTextBox As clsBusinessCaseTextBoxEvents)
Public Property Set UserForm(frmUserForm As UserForm)
Set objUserForm = frmUserForm
End Property
Public Property Get UserForm() As UserForm
Set UserForm = objUserForm
End Property
Public Function AddTextBox() As clsBusinessCaseTextBoxEvents
Dim objTextBox As clsBusinessCaseTextBoxEvents
Set objTextBox = New clsBusinessCaseTextBoxEvents
'
objTextBox.Initialize Me
End Function
Private Sub Class_Initialize()
Set colCollection = New Collection
End Sub
and as a sample in this class
Public Sub Enter(objTextBox As clsBusinessCaseTextBoxEvents)
RaiseEvent Enter(objTextBox)
End Sub
And then in a normal module to add a textbox class
Dim objTextBoxControl As control
Set objTextBoxControl = frmBusinessCase.mtpBusinessCase.Page0.Controls.Add("Forms.TextBox.1", strTextBoxName, True)
As noted, when I enter the class textbox - when it is on a form - the 'OnEnter' event fires normally. But not when the class textbox is placed on a multipage on the form.
Can anyone help? Thx, JonS
Hi Rory, is this what you mean?
'==================================================================================================================
'############ Section BEGIN for: OnEnter, OnExit, BeforeUpdate and AfterUpdate ####################################
'------------------------------------------------------------------------------------------------------------------
'
'Unlike VB, VBA does not bring across the 'OnEnter, 'OnExit', 'BeforeUpdate' and 'AfterUpdate' events as methods
'into it's textbox class.
'
'Instead, to obtain this functionality, it is necessary to make a Windows API call to 'ConnectToConnectionPoint'
'
'The code in these partitioned blocks deals with these functions using this Windows API call
'------------------------------------------------------------------------------------------------------------------
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(0 To 7) As Byte
End Type
#If VBA7 Then
Private Declare PtrSafe Function IIDFromString Lib "ole32.dll" (ByVal lpsz As LongPtr, lpiid As GUID) As Long
Private Declare PtrSafe Function ConnectToConnectionPoint Lib "shlwapi" Alias "#168" (ByVal punk As stdole.IUnknown, ByRef riidEvent As GUID, ByVal fConnect As Long, ByVal punkTarget As stdole.IUnknown, ByRef pdwCookie As Long, Optional ByVal ppcpOut As LongPtr) As Long
#Else
Private Declare PtrSafe Function IIDFromString Lib "ole32.dll" (ByVal lpsz As Long, lpiid As GUID) As Long
Private Declare PtrSafe Function ConnectToConnectionPoint Lib "shlwapi" Alias "#168" (ByVal punk As stdole.IUnknown, ByRef riidEvent As GUID, ByVal fConnect As Long, ByVal punkTarget As stdole.IUnknown, ByRef pdwCookie As Long, Optional ByVal ppcpOut As Long) As Long
#End If
'==================================================================================================================
'############ Section END for: OnEnter, OnExit, BeforeUpdate and AfterUpdate ####################################
'==================================================================================================================
'==================================================================================================================
'############ Section BEGIN for: OnEnter, OnExit, BeforeUpdate and AfterUpdate ####################################
'==================================================================================================================
Public Property Let SetControlEvents(ByVal TextBox As Object, ByVal SetEvents As Boolean)
Const S_OK = &H0
Static lCookie As Long
Dim tIID As GUID
Set objTextBox = TextBox
If IIDFromString(StrPtr("{00020400-0000-0000-C000-000000000046}"), tIID) = S_OK Then
Call ConnectToConnectionPoint(Me, tIID, SetEvents, TextBox, lCookie)
If lCookie Then
'Debug.Print "Connection set for: " & TextBox.Name
'MsgBox "Connection set for: " & TextBox.Name
Else
'Debug.Print "Connection failed for: " & TextBox.Name
End If
End If
End Property
Public Sub OnEnter()
'Attribute OnEnter.VB_UserMemId = &H80018202
'Debug.Print "[ENTER EVENT] " & oTextBox.Name & vbTab & "Value: " & vbTab & oTextBox.Value
MsgBox "On Enter"
Call TurnActiveFieldToYellow(objTextBox)
Call FormBusinessCaseDollarFieldsBlue(objTextBox)
End Sub

Answer 1

The whole issue appeared when placing class textboxes on a 'multipage' on a form, rather than the form itself (which does not cause this problem)
I am not strong on classes. However, the suggestion of gathering all of the textbox objects into a collection (after they have been created) and then hooking them up to the class, like in this link, got the events working again. You could probably improve on my code below.
To solve, and after the class textboxes have been created using the 'add controls' method.
Dim objTextBoxControl As Control
Set objTextBoxControl = frmBusinessCase.mtpBusinessCase.Page0.Controls.Add("Forms.TextBox.1", strTextBoxName, True)
I used this in an ordinary module and call the sub 'InitialiseEvents' once the textboxes have been created
Dim colCollection As Collection
Sub InitializeEvents()
Dim ctl As Object
Dim clsEvents As clsBusinessCaseTextBoxEvents
If colCollection Is Nothing Then
Set colCollection = New Collection
End If
'Loop through all the controls
For Each ctl In frmBusinessCase.Controls
If TypeName(ctl) = "TextBox" Then
'Create a new instance of the event handler class
Set clsEvents = New clsBusinessCaseTextBoxEvents
'Tell it to handle the events for the text box
Set clsEvents.Control = ctl
'Add the event handler instance to our collection,
'so it stays alive during the life of the workbook
colCollection.Add clsEvents
End If
Next
End Sub
Sub TerminateEvents()
'Here the collection of classes is destroyed so memory will be freed up:
Set colCollection = Nothing
End Sub
and then added this to, or have present in, the class module 'clsBusinessCaseTextBoxEvents':
Public WithEvents objTextBox As MSForms.TextBox
Private objParent As clsBusinessCaseEventControl
Public Property Set Control(objTextBoxNew As MSForms.TextBox)
Set objTextBox = objTextBoxNew
End Property
Private Sub Class_Terminate()
Set objTextBox = Nothing
End Sub