VBA: Adding an identifier to values in column if there are duplicates - excel

Question

I am trying to assign a identifier to the back of the string if there are duplicate values.
I considered a for loop with a counter but it simply gave me a sequence of numbers in each cells.
Is there another way I can approach this matter?
Sub Macro1()
For i = 1 To 10
For N = 1 To 10
If Worksheets("sheet1").Range("A" & i) = Worksheets("sheet1").Range("A" & N) Then
Worksheets("sheet1").Range("A" & i) = Worksheets("sheet1").Range("A" & i) & counter
counter = counter + 1
End If
Next N
Next i
End Sub

Answer 1

There might be other solutions, but this is what I actually came up with.
Don't forget to add this reference to your project:
Tools -> References -> Microsoft Scripting Runtime -> tick checkbox
Sub Macro1()
' Add reference to project:
' Tools -> References -> Microsoft Scripting Runtime -> tick checkbox
Dim dDict As New Scripting.Dictionary
Dim rngInput As Range
Dim sOutputCol As String
Dim lRow As Long, lCount As Long
With ThisWorkbook.Worksheets("SHEET_NAME") ' SHEET_NAME: the name of the sheet where input is
Set rngInput = .Range("A1:A10") ' A1:A10: the range on the sheet where input is
sOutputCol = "C" ' sOutputCol: output column's letter
For lRow = rngInput.Rows(1).Row To rngInput.Rows(rngInput.Rows.Count).Row
If dDict.Exists(rngInput.Cells(lRow, 1).Value2) Then
lCount = dDict(rngInput.Cells(lRow, 1).Value2)
dDict.Remove rngInput.Cells(lRow, 1).Value2
dDict.Add rngInput.Cells(lRow, 1).Value2, lCount + 1
Else
dDict.Add rngInput.Cells(lRow, 1).Value2, 1
End If
.Cells(lRow, sOutputCol).Value2 = rngInput.Cells(lRow, 1).Value2 & "_" & dDict(rngInput.Cells(lRow, 1).Value2)
Next lRow
End With
End Sub

Answer 2

Here's a slightly different Dictionary approach, which gives you an array of the final values.
Sub Tester()
Dim arr, r As Long, dict As Object, rng As Range, v, tmp
Set dict = CreateObject("scripting.dictionary")
Set rng = ActiveSheet.Range("B1:B20")
arr = rng.Value 'get the input values in an array
For r = 1 To UBound(arr, 1) 'loop over all the values
v = arr(r, 1)
If Not dict.exists(v) Then 'new value?
dict.Add v, Array(r, 1) 'store row for the first occurence and start the count
Else
tmp = dict(v) 'not new value: pull array from dict
tmp(1) = tmp(1) + 1 'increment count for this value
If tmp(1) = 2 Then arr(tmp(0), 1) = arr(tmp(0), 1) & "_1" 'second instance? Flag the first occurence also...
arr(r, 1) = arr(r, 1) & "_" & tmp(1) 'flag the n'th instance
dict(v) = tmp 're-store the array
End If
Next r
rng.Offset(0, 2).Value = arr 'output the (updated) array
End Sub