Multiplying Values in a Form - excel

Question

I am trying to create a form that requires an input from the user, and multiplies this input by the value in a cell from a different worksheet. For some reason, when I run the code the value comes out as 0. Is there anything wrong with my code?
Sub PartOrder()
Dim qty As Variant
qty = Application.InputBox("How many assemblies are needed?")
Sheets.Add After:=Worksheets(Sheets.Count)
PartOrderForm.Show
End Sub
Private Sub CompleteForm_Click()
If CheckBox1.Value = True Then
ActiveSheet.Range("A1") = "Part Number"
ActiveSheet.Range("B1") = "Part Name"
ActiveSheet.Range("C1") = "Number of Parts Needed"
ActiveSheet.Range("A2") = Worksheets("F8X SUSPENSION LINKS REV2").Range("B7")
ActiveSheet.Range("B2") = Worksheets("F8X SUSPENSION LINKS REV2").Range("C7")
ActiveSheet.Range("C2") = Worksheets("F8X SUSPENSION LINKS REV2").Range("F7") * qty
Else: End If
End Sub

Answer 1

Specifying Option Explicit at the top of your form module (it should be at the top of every module, actually) would have given you a compile error giving you a hint for what's going on: the qty variable is not in scope in the form module (hence the "variable not declared" compile error with Option Explicit), so you're multiplying by a Variant/Empty value that equates to 0.
Find a way to get qty (or a copy of it) in-scope in the form module - either by promoting it to module-level (and making it Public), or otherwise passing it as a parameter to the form - perhaps using a property, like so:
Option Explicit '<<<<< should be in EVERY module
Private localQty As Double
Public Property Get Qty() As Double
Qty = localQty
End Property
Public Property Let Qty(ByVal Value As Double)
localQty = Value
End Property
' now use either Qty or localQty for the multiplication
The calling code only needs to pass the value before showing the form:
Qty = Application.InputBox("How many assemblies are needed?")
If IsNumeric(Qty) Then
With New PartOrderForm
.Qty = Qty
.Show
End With
End If