Merging Word docs with Excel as variable data - excel

Question

I'm trying to work out a simple way to get "variable" data into a Word docs.
I have a client who is supplying Word templates for various procedures. This would form a document that goes out to several locations, with personalized information for each location.
This could be done with a simple Mail Merge from Excel, but there are additional issues:
The doc will contain tables with supervisor contact information. It's the general info: Name, phone contacts, email, etc. But there could be 1 to 5 contacts. I could see that would mean several rows with the same key, meaning several copies where I only want one.
Is there an "easy" way to merge data into both document text and tables? The idea is to present the client with a "goof proof" solution so they can easily update the template and the data files.
I'm also looking at using Word variables, but one source said I'd be limited to 15 variable in a document.
Any ideas will be greatly appreciated. Also looking up previous questions on this stack.

Answer 1

One option would be to use a DATABASE field in a normal ‘letter’ mailmerge main document and a macro to drive the process. Here is an outline of this approach:
Suppose you have a data set that has fields for the subordinates' Firstname, Surname, Employee ID, & Job Title, and that against each record is recorded their Manager's ID, whose email address is also recorded. Let's also assume the mailmerge main document is kept in the same folder as the data source. In that case, you could use a DATABASE field coded as:
{DATABASE \d "{FILENAME \p}/../MM datasource.xlsx" \s " SELECT [Firstname], [Surname], [Employee ID], [Job Title] FROM [Sheet1$] WHERE [Manager ID] = {MERGEFIELD Manager_ID} ORDER BY [Job Title] " \l "15" \b "49" \h}
in an email merge, where 'MM datasource.xlsx' is the data source filename - it could even be an Access database filename, if that's what you chose to use. If the mailmerge main document is NOT kept in the same folder as the data source, you'd need to replace all of "{FILENAME \p}/../MM datasource.xlsx" with the full path & filename (plus the encompassing double-quotes). The \l and \b switches control the table format, while the \h switch inserts a table header row - see: https://support.office.com/en-us/article/Field-codes-Database-field-04398159-a2c9-463f-bb59-558a87badcbc?ui=en-US&rs=en-US&ad=US
Note: The field brace pairs (i.e. '{ }') for the above example are all created in the document itself, via Ctrl-F9 (Cmd-F9 on a Mac); you can't simply type them or copy & paste them from this post. Nor is it practical to add them via any of the standard Word dialogues. The spaces represented in the field constructions are all required.
Then, to drive the process, you could use a macro like:
Sub Merge_by_Group()
Application.ScreenUpdating = False
Dim MainDoc As Document, StrMgrID As String, i As Long
Set MainDoc = ActiveDocument
With MainDoc
For i = 1 To .MailMerge.DataSource.RecordCount
With .MailMerge
.Destination = wdSendToEmail
.SuppressBlankLines = True
With .DataSource
.FirstRecord = i
.LastRecord = i
.ActiveRecord = i
End With
If .DataSource.DataFields("Manager_ID") <> StrMgrID Then
StrMgrID = .DataSource.DataFields("Manager_ID")
.MailAddressFieldName = "Email"
.MailSubject = "Your Team's Details"
.MailFormat = wdMailFormatHTML
.Execute Pause:=False
End If
End With
Next i
End With
Application.ScreenUpdating = True
End Sub
A merge to email is assumed, but not necessary. If you want the output to go to a Word document, change:
.Destination = wdSendToEmail
to:
.Destination = wdSendToNewDocument
and delete:
.MailAddressFieldName = "Email"
.MailSubject = "Your Team's Details"
.MailFormat = wdMailFormatHTML
Note: If you rename the above macro as 'MailMergeToEmail' (or 'MailMergeToDoc' to send the output to a document), clicking on the 'Send Email Messages' (or 'Edit Individual Documents') button will intercept the merge and the process will run automatically. The potential disadvantage of intercepting the 'Send Email Messages' (or 'Edit Individual Documents') process this way is that you no longer get to choose which records to merge at that stage. However, you can still achieve the same outcome - and with greater control - via the 'Edit Recipient List' tools.
Conversely, if you're using a relational database or, an Excel workbook with a separate table listing each of the grouping criteria (e.g. the Manager_ID & email address) and any other fields that occur once per group, a DATABASE field in a normal ‘letter’ or 'email' mailmerge main document could be used without the need for a macro. In this case, the same DATABASE field would be used, but the mailmerge would be connected to the Excel worksheet (or database table) containing just the Manager_IDs and Names. For some working examples of this approach, see:
https://www.msofficeforums.com/mail-merge/37844-mail-merge-using-one-excel-file-multiple.html
https://www.msofficeforums.com/mail-merge/45044-using-mailmerge-include-grouped-information-letter-2.html#post151706
https://www.excelforum.com/excel-general/1273421-merge-excel-list-into-word-receipt.html#post5110813
(the second of these uses a macro to apply some additional formatting).
If you'd like to have each group's mailmerge output from the second approach saved as a separate document/pdf, see the Send Mailmerge Output to Individual Files topic in my Mailmerge Tips & Tricks page: https://www.msofficeforums.com/mail-merge/21803-mailmerge-tips-tricks.html