VBA dictionary and class module - excel

Question

The code breaks here
ws.Cells(j, "M").Value = dict(ws.Cells(j, "H").Value).volume
ws.Cells(j, "N").Value = dict(ws.Cells(j, "H").Value).rate
I believe the issue is trying to retrieve the dictionary value when the key is dynamic so
dict(ws.Cells(j, "H").Value).volume errors out
but
dict(5455).volume
will work.
Am I correct that this is the issue and any solutions?
Sub RetrieveData()
Dim dict As New Dictionary
Dim group As clsgroup
Dim lrowRetrieve As Long, lrowLookup As Long
Dim ws As Worksheet
Dim i As Long, j As Long, name As String, rate As Long, volume As Long
lrowRetrieve = Cells(Rows.Count, "C").End(xlUp).Row
lrowLookup = Cells(Rows.Count, "H").End(xlUp).Row
Set ws = Sheets("Test")
dict.RemoveAll
For i = 1 To lrowRetrieve
'add criteria for month/year of reporting
If ws.Cells(i, "C").Value <> "" And ws.Cells(i, "C").Value <> 0 And ws.Cells(i, "G").Value <> "" And ws.Cells(i, "G").Value <> 0 Then
name = ws.Cells(i, "C").Value
If dict.Exists(name) = False Then
Set group = New clsgroup
group.name = name
dict.Add key:=group.name, Item:=group
Else
Set group = dict(name)
'dict(ws.Cells(i, "C").Value) = ws.Cells(i, "G").Value
End If
With group
.rate = .rate + ws.Cells(i, "F").Value
.volume = .volume + ws.Cells(i, "G").Value
End With
End If
Next i
Dim key As Variant
For Each key In dict
Set group = dict(key)
With group
Debug.Print .name, .rate, .volume
End With
Next key
For j = 25 To lrowLookup
Select Case ws.Cells(j, "H").Value
Case "5455"
If ws.Cells(j, "K").Value = "Medical" Then
ws.Cells(j, "M").Value = dict("5455/5456").volume
ws.Cells(j, "N").Value = dict("5455/5456").rate
Else
ws.Cells(j, "M").Value = dict("5455/5456 (non med)").volume
ws.Cells(j, "N").Value = dict("5455/5456 (non med)").rate
End If
Case Else
Debug.Print ws.Cells(j, "H").Value
ws.Cells(j, "M").Value = dict(ws.Cells(j, "H").Value).volume
ws.Cells(j, "N").Value = dict(ws.Cells(j, "H").Value).rate
End Select
Next j
End Sub

Answer 1

dict(5455) is not the same as dict("5455") - it matters what data type your keys have when they're added - reliable retrieval from the dictionary requires the same type be used....
You might find it best to always convert your keys to String before adding them, and always retrieve with String-type keys
Sub Tester()
Dim dict As Object
Set dict = CreateObject("scripting.dictionary")
dict(5455) = "Numeric"
dict("5455") = "String" '"5455" is a different key from 5455 !
Debug.Print dict(5455) '>> "Numeric"
Debug.Print dict("5455") '>> "String"
End Sub