Can you assign a the value of a rich data type into a variable in Excel VBA? - excel

Question

I am trying to save the ticker symbol I derived using a Rich data type (I am not sure if I said it correctly) from B2 to a variable.
I used this code
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Ticker As String
If Target.Address = "$A$2" Then
Ticker = Activesheet.Range("B2").Value
MsgBox Ticker
End If
End Sub
It happens when I make changes to A2.
I tried to convert it into text or string and it does not work. I assigned the variable as a Variant and String, but still, it won't work. Error is saying "Run time error'13' Type mismatch. But I cannot figure out where I did wrong.
When I debug it, Ticker = ""
I googled around and I cannot find an answer. Is it possible though?

Answer 1

Problem: when you change the rich data type in A2, Excel starts retrieving the ticker symbol in B2 via =A2.[Ticker symbol]. Fetching such data might take a short while, and while the request is pending, B2 will show as #FIELD!. While in this state, B2.Value will be read as an error, so that your code will bounce on Ticker = ActiveSheet.Range("B2").Value, since the variable is dimmed as String. This is why you get the "Type mismatch" error.
Solution: Build a slight delay into your code that will give Excel sufficient time to retrieve the requested data. We can use a Do While Loop for this. Define 2 booleans:
First boolean checks IsError(ActiveSheet.Range("B2"))
Second boolean functions as a timer
Exit the loop when either of these booleans becomes False. You want to include the second boolean to ensure that you do not end up in an infinite loop. This might otherwise happen if the value in B2 will always remain #FIELD, because you didn't supply a valid entry in A2.
Something like the following should work:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Ticker As String
Dim fieldError As Boolean, onTime As Boolean
Dim endTime As Date
'using Target.Text <> "" rather than Target.Value <> "", since the latter will throw an error
'if the range contains a 'rich data type'
If Not Intersect(Target, ActiveSheet.Range("A2")) Is Nothing And Target.Text <> "" Then
'set timeframe to wait for response, set to 1 second here
'we want to check: if "#FIELD!" hasn't changed into a proper value after 1 second
'then data in A2 is probably nonsense: exit loop
endTime = Now + TimeValue("00:00:01")
'set Booleans
onTime = True
fieldError = True
'enter Do While Loop
Do While fieldError And onTime 'continue until
If IsError(ActiveSheet.Range("B2")) Then
Else
'B2 (no longer) an error, switch bool to False to exit loop
fieldError = False
End If
'bool to False after time out to exit loop
onTime = Now < endTime
Loop
'In case of Error, probably incorrect input in A2
On Error GoTo ErrorHandling
Ticker = ActiveSheet.Range("B2").Value
ErrorHandling:
Debug.Print "A2.Text = " & ActiveSheet.Range("A2").Text & "), " & _
"ticker = " & Ticker & ", fieldError = " & fieldError & ", onTime = " & onTime
If Err.Number <> 0 Then
'do stuff (you probably got a correct response, but it's still an error
Debug.Print "Entered ErrorHandling"
Err.Number = 0
End If
Debug.Print "------"
Else
End If
End Sub
To exemplify, below you see a loop in action that populates A2 with a reference to items in the range LIST successively and tries to retrieve the ticker. Notice the output in the immediate window: for "AA", "AAPL" and "AMZN" we are exiting the loop on fieldError = False (ticker found). For "NONSENSE" we are exiting on onTime = False (no ticker: we timed out).