VBA keeps pasting number stores as texts - excel

Question

I'd like VBA to stop copy pasting my top headers with the green ribbon stating "numbers are stores as texts". Is there any way to get around it? I'm trying to copy and paste financial data from another excel sheet onto my main sheet. Here's the Code. Thank you in advance.
Sub God()
'Delete all data from the ranges
ThisWorkbook.Worksheets("10k I").Cells.Clear
ThisWorkbook.Worksheets("10k B").Cells.Clear
ThisWorkbook.Worksheets("10k C").Cells.Clear
ThisWorkbook.Worksheets("10q I").Cells.Clear
ThisWorkbook.Worksheets("10q B").Cells.Clear
ThisWorkbook.Worksheets("10q C").Cells.Clear
'Open workbook Income statement
Workbooks.Open "/Users/krabbysponge/Downloads/1.xls"
Workbooks.Open "/Users/krabbysponge/Downloads/2.xls"
Workbooks.Open "/Users/krabbysponge/Downloads/3.xls"
Workbooks.Open "/Users/krabbysponge/Downloads/4.xls"
Workbooks.Open "/Users/krabbysponge/Downloads/5.xls"
Workbooks.Open "/Users/krabbysponge/Downloads/6.xls"
'Copy range to another workbook
Workbooks("1.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10k I").Range("A1")
Workbooks("2.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10k B").Range("A1")
Workbooks("3.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10k C").Range("A1")
Workbooks("4.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10q I").Range("A1")
Workbooks("5.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10q B").Range("A1")
Workbooks("6.xls").Worksheets(1).Range("A1:M150").Copy _
ThisWorkbook.Worksheets("10q C").Range("A1")
'Close workbook Income statement
Workbooks("1.xls").Close SaveChanges:=True
Workbooks("2.xls").Close SaveChanges:=True
Workbooks("3.xls").Close SaveChanges:=True
Workbooks("4.xls").Close SaveChanges:=True
Workbooks("5.xls").Close SaveChanges:=True
Workbooks("6.xls").Close SaveChanges:=True
End Sub

Answer 1

You don't need to copy - but can write the value direct to the target sheet.
This has two advantages:
you don't use the clipboard
therefore it is much faster
According to "Don't repeat yourself" (DRY) you can put everything in a for-loop - and configuring your files in an array. In case there are changes to this setting it is much easier to adapt the code.
Public Sub copyData()
Dim arrConfig(1, 2) As String
'Target sheetname | Source filename
arrConfig(0, 0) = "10k I": arrConfig(1, 0) = "1.xls"
arrConfig(0, 1) = "10k B": arrConfig(1, 1) = "2.xls"
arrConfig(0, 2) = "10k C": arrConfig(1, 2) = "3.xls"
'...
'arrconfig(0,6) = ...
Const pathDownloads As String = "/Users/krabbysponge/Downloads/"
Const AddressToCopy As String = "A1:M150"
Dim i As Long, wbSource As Workbook, wsSource As Worksheet, wsTarget As Worksheet
For i = 0 To UBound(arrConfig, 2)
Set wsTarget = ThisWorkbook.Worksheets(arrConfig(0, i))
wsTarget.Cells.Clear
Set wbSource = Workbooks.Open(pathDownloads & arrConfig(1, i))
Set wsSource = wbSource.Worksheets(1)
'This is the part where the data are written from one range to another (values only without formatting)
wsTarget.Range(AddressToCopy).Value = wsSource.Range(AddressToCopy).Value
wbSource.Close savechanges:=True
Next
End Sub