Excel if else formula fails due to wrong syntex - excel

Question

I have different class name in excel column in character form. I want to convert it to numerical form and add in column C
If B2==N, make it 1
If B2==O, make it 0
If B2==A, make it 2
If B2==~, make it 9
I have written the following excel formula. I have added my formula and error message in image. Can you correct me where I am making mistake
=IF(B2='N',1,if(b2='O',0,if(b2='A',2,if(b2='~',9))))
Update
After adding the formula as per details answer

Answer 1

Personally I would do something like this, using IFS function:
=IFS(B2="N",1,B2="O",0,B2="A",2,B2="~",9)

Answer 2

Within Excel formulas, double quotes are used to denote the start and end of a text string. Numeric should not be within double quotes.
That said, we can use a formula like IF function but we can also avoid using double quotes by creating a table of reference, refer the image below, for alternative solutions - 7 APPROACHES
• Formula used in cell C2
=VLOOKUP($B2,$I$2:$J$5,2,1)
Without Table Of Reference the above formula can be written as
=VLOOKUP($B2,{"~",9;"A",2;"N",1;"O",0},2,1)
• Formula used in cell D2
=LOOKUP($B2,$I$2:$J$5)
Without Table Of Reference the above formula can be written as
=LOOKUP($B2,{"~",9;"A",2;"N",1;"O",0})
• Formula used in cell E2 --> "Correction To Your Own Formula"
=IF(B2="N",1,IF(B2="O",0,IF(B2="A",2,IF(B2="~",9))))
• Formula used in cell F2
=IFS(B2="~",9,B2="A",2,B2="N",1,B2="O",0)
• Formula used in cell G2
=SWITCH($B2,"~",9,"A",2,"N",1,"O",0)
Note the formulas used in cell F2 & G2 you need to have either Excel 2019, Excel 2021 Or O365 hence its better to use a Table Of Reference to avoid using Double Quotes.
So, if there is a space before each characters then the formula, shall change refer the image below and & the formulas,
• Formula used in cell C2
=VLOOKUP(TRIM($B2),$I$2:$J$5,2,1)
• Formula used in cell D2
=LOOKUP(TRIM($B2),$I$2:$J$5)
• Formula used in cell E2
=IF(TRIM($B2)="N",1,IF(TRIM($B2)="O",0,IF(TRIM($B2)="A",2,IF(TRIM($B2)="~",9))))
• Formula used in cell F2
=IFS(TRIM($B2)="~",9,TRIM($B2)="A",2,TRIM($B2)="N",1,TRIM($B2)="O",0)
• Formula used in cell G2
=SWITCH(TRIM($B2),"~",9,"A",2,"N",1,"O",0)
And if those are not spaces and actually are non printable characters then just change the TRIM to SUBSTITUTE Function
C2
=VLOOKUP(SUBSTITUTE($B2,CHAR(160),""),$I$2:$J$5,2,1)
D2
=LOOKUP(SUBSTITUTE($B2,CHAR(160),""),$I$2:$J$5)
E2
=IF(SUBSTITUTE($B2,CHAR(160),"")="N",1,IF(SUBSTITUTE($B2,CHAR(160),"")="O",0,IF(SUBSTITUTE($B2,CHAR(160),"")="A",2,IF(SUBSTITUTE($B2,CHAR(160),"")="~",9))))
F2
=IFS(SUBSTITUTE($B2,CHAR(160),"")="~",9,SUBSTITUTE($B2,CHAR(160),"")="A",2,SUBSTITUTE($B2,CHAR(160),"")="N",1,SUBSTITUTE($B2,CHAR(160),"")="O",0)
G2
=SWITCH(SUBSTITUTE($B2,CHAR(160),""),"~",9,"A",2,"N",1,"O",0)

Answer 3

In Excel, double quotes is used to enclose character values not single quote. Hence, your formula will become
=IF(B2="N",1,IF(B2="O",0,IF(B2="A",2,IF(B2="~",9,""))))
Additionally, I have added an else clause with blanks in last IF.
Also, if you are on newer versions of Excel, then you can also use SWITCH which is easier and shorter
=SWITCH(B2,"N",1,"O",0,"A",2,"~",9,"")