Correct usage of AtomicCmpExchange? - multithreading

Question

After struggling to avoid deadlocks using Synchronize() with DirectShow I decided to switch to an optimistic lock pattern. This is my first time using AtomicCmpExchange() and I found very few Delphi examples online. I don't see any downside and don't know why more thread locking isn't done this way.
What are the pitfalls of the following code? The lack of examples make me concerned that there is a fundamental flaw with this approach.
procedure TCueRunner.Lock(Desc: String);
begin
// cs.Enter;
var StopWatch := TStopwatch.StartNew;
while (AtomicCmpExchange(LockAtomic, 1, 0) = 1) do
begin
Sleep(1);
if StopWatch.ElapsedMilliseconds > MUTEX_TIMEOUT then
begin
LockAtomic := 0;
LogMsg('CRITICAL! TCueRunner lock timed out in function '+Desc);
break;
end;
end;
end;
procedure TCueRunner.Unlock;
begin
LockAtomic := 0; // This should be an atomic operation
// cs.Leave;
end;

Answer 1

First, your lock cannot be recursively used. It's not always an issue, but it's usually worth it to make it work recursively as it's pain to always make sure it's not used in this fashion.
Second, as commented by Dalija, it's not really an expected behavior that a lock attempt that timeout would cause the lock to be automatically unlocked.
Third, if locking fails, your method should raise an exception, otherwise, the calling code will proceed as if the lock had succeeded. Alternately, you could change your method to a function returning a boolean indicating if the lock succeeded or not.
If I adapt your code, that would give something like this (Untested) :
procedure TCueRunner.Lock(Desc: String);
begin
var StopWatch := TStopwatch.StartNew;
repeat
var PrevLockValue := AtomicCmpExchange(LockAtomic, TThread.CurrentThread.ThreadID, 0);
if PrevLockValue = 0 then //wasn't locked
FLockCount := 1
else if PrevLockValue = TThread.CurrentThread.ThreadID then //Was locked previously, but by the current thread.
Inc(FLockCount)
else
begin //Is locked by another thread
Sleep(1);
if StopWatch.ElapsedMilliseconds > MUTEX_TIMEOUT then
raise Exception.Create('CRITICAL! TCueRunner lock timed out in function '+Desc);
CONTINUE;
end;
BREAK;
until False;
end;
procedure TCueRunner.Unlock;
begin
if LockAtomic = TThread.CurrentThread.ThreadID then
begin
Dec(FLockCount);
if FLockCount = 0 then
LockAtomic := 0;
end else
LogMsg('Unlocking from the wrong thread!!!!');//Or not locked...
end;
Note : This should work properly on WIN32/64, I'm unsure about other platforms.