Copy entire row from one workbook to another - excel

Question

I need a macro that can copy the entire row from the workbook I am in based on the cell I have selected. I can do this already, using the following:
ActiveCell.EntireRow.Select
Selection.Copy
But then, I need it to paste that (formatting and all) into the first empty row (based on column B) of a workbook that is closed. R:\dasboards\wo.xlsm

Answer 1

Backup Entire Row to a Closed Workbook
Adjust the values in the constants section.
Option Explicit
Sub BackupEntireRow()
Const dFilePath As String = "R:\DashBoards\wo.xlsm"
Const dwsName As String = "Sheet1"
Const dlrCol As String = "B"
Dim IsSuccess As Boolean
If TypeName(Selection) <> "Range" Then
MsgBox "No cells selected.", vbCritical
Exit Sub
End If
Dim dwbName As String: dwbName = Dir(dFilePath)
If Len(dwbName) = 0 Then
MsgBox "Could not find the destination file" _
& vbLf & "'" & dFilePath & "'", vbCritical
Exit Sub
End If
Dim srrg As Range: Set srrg = ActiveCell.EntireRow
Dim dwb As Workbook
Dim dDoCloseWorkbook As Boolean
On Error Resume Next
Set dwb = Workbooks(dwbName)
On Error GoTo 0
If dwb Is Nothing Then
Set dwb = Workbooks.Open(dFilePath)
dDoCloseWorkbook = True
End If
Dim dws As Worksheet
On Error Resume Next
Set dws = dwb.Worksheets(dwsName)
On Error GoTo 0
If dws Is Nothing Then
If dDoCloseWorkbook Then
dwb.Close SaveChanges:=False
End If
MsgBox "The destination worksheet '" & dwsName & "' doesn't exist.", _
vbCritical
Exit Sub
End If
Dim dCell As Range
Set dCell = dws.Cells(dws.Rows.Count, dlrCol).End(xlUp).Offset(1)
Dim drrg As Range: Set drrg = dCell.EntireRow
srrg.Copy drrg
If dDoCloseWorkbook Then
dwb.Close SaveChanges:=True
Else
dwb.Save
End If
IsSuccess = True
If IsSuccess Then
MsgBox "Row backed up.", vbInformation
End If
End Sub