Creating an IFERROR using INDEX/MATCH formula in VBA Code - excel

Question

I have a VBA tool I'm trying to update by inputting an IFERROR formula into column B on Sheet2 using INDEX/MATCH to pull the data from column F in Sheet 1. The matching criteria is looking at column D in the active row of Sheet 2 and matching it to Column J in Sheet 1.
The resulting formula should look like this
=IFERROR(INDEX(Sheet1!$F:$F,MATCH('Sheet2'!$D2,Sheet1!$J:$J,0)),"")
This is the code I wrote but I'm getting the "Unable to set formulaaray property of the range class" error.
Range("B2").FormulaArray = "=IFERROR(INDEX(Sheet1,C6,MATCH(RC2,Sheet1,RC10,0)),"""")"
I'm still rather new to VBA and in my research I haven't found anything to help. Appreciate any help anyone can give me in solving this error.
I'm trying to adapt/change the current formula coded in the tool to the above. This code was working it's just the user has made some changes to the file and now wants to grab the data as described in my original post.
Range("B2").FormulaArray = "=IFERROR(INDEX(C6,MATCH(RC1&R1C2,C1&C5,0)),"""")": Range("B2:B" & LastRow).FillDown
Range("B:b").EntireColumn.Select
Selection.Copy
Selection.PasteSpecial xlPasteValues

Answer 1

A VBA Lookup (INDEX/MATCH formula)
Adjust the values in the constants section.
Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Returns the results of an 'INDEX/MATCH' formula as values.
' Formula: '=IFERROR(INDEX(Sheet1!$F:$F,MATCH(D2,Sheet1!$J:$J,0)),"")'
' Remarks: 'VLOOKUP' doesn't work because 'F' is to the left of 'J':
' wrong '=VLOOKUP(D2,Sheet1!$J:$F,-5,0)' wrong.
' Calls: 'RefColumn'.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub VBALookupFormula()
' Source
Const sName As String = "Sheet1"
Const slCol As String = "J" ' 2. lookup (compare (match))
Const svCol As String = "F" ' 3. value (return)
Const sfRow As Long = 2
' Destination
Const dName As String = "Sheet2"
Const dlCol As String = "D" ' 1. lookup (read)
Const dvCol As String = "B" ' 4. value (write)
Const dfRow As Long = 2
' Workbook
Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
Dim sws As Worksheet: Set sws = wb.Worksheets(sName)
Dim slrg As Range: Set slrg = RefColumn(sws.Cells(sfRow, slCol))
If slrg Is Nothing Then Exit Sub ' no data
Dim dws As Worksheet: Set dws = wb.Worksheets(dName)
Dim dlrg As Range: Set dlrg = RefColumn(dws.Cells(dfRow, dlCol))
If dlrg Is Nothing Then Exit Sub ' no data
Dim slAddress As String: slAddress = slrg.Address
Dim svAddress As String: svAddress = slrg.EntireRow.Columns(svCol).Address
Dim dlAddress As String: dlAddress = dlrg.Cells(1).Address(0, 0)
Dim dvrg As Range: Set dvrg = dlrg.EntireRow.Columns(dvCol)
Dim dFormula As String
' Note the 4 single quotes (necessary when a worksheet name contains spaces)
' and the 4 consecutive double quotes (basically one double quote
' in the formula is two double quotes in VBA).
dFormula = "=IFERROR(INDEX('" _
& sName & "'!" & svAddress & ",MATCH(" & dlAddress & ",'" _
& sName & "'!" & slAddress & ",0)),"""")"
dvrg.Formula = dFormula
dvrg.Value = dvrg.Value
MsgBox "The lookup finished successfully.", vbInformation
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Creates a reference to the one-column range from the first cell
' of a range ('FirstCell') to the bottom-most non-empty cell
' of the first cell's worksheet column.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function RefColumn( _
ByVal FirstCell As Range) _
As Range
If FirstCell Is Nothing Then Exit Function
With FirstCell.Cells(1)
Dim lCell As Range
Set lCell = .Resize(.Worksheet.Rows.Count - .Row + 1) _
.Find("*", , xlFormulas, , , xlPrevious)
If lCell Is Nothing Then Exit Function
Set RefColumn = .Resize(lCell.Row - .Row + 1)
End With
End Function