Powerquery - Converting single column information having column names and values to table - transform

Question

I have a data in a single column as under
CName1
CName2
CName3
.
.
.
row1 col1 value1
row1 col2 value2
row1 col2 value3
.
.
.
row2 col1 value4
row2 col2 value5
row2 col3 value6
.
.
.
row3 col1 value7
row3 col2 value8
row3 col3 value9
.
.
.
.
What I would like to have is
CName1
CName2
CName3
.....
.....
.....
Value1
value2
value3
.....
.....
.....
Value4
value5
value6
.....
.....
.....
Value7
value8
value9
.....
.....
.....
.....
.....
.....
.....
.....
How can this be achieved ?
Thanks for help.

Answer 1

Here's one method:
Assumptions
The positional entries in each data row are not really there
if they are, we would modify the algorithm
All column headers are in the first group
each group is separated by at least one empty row
each group's columns start with the first (but they don't all have to have the same number of columns)
Please read the code comments, and explore the Applied Steps window, to understand the algorithm
M Code
edited to remove hard-coded column names from last line
let
Source = Excel.CurrentWorkbook(){[Name="Table12"]}[Content],
#"Changed Type" = Table.TransformColumnTypes(Source,{{"Column1", type text}}),
//add shifted column
shifted = Table.FromColumns(
Table.ToColumns(#"Changed Type") &
{{null} & List.RemoveLastN(#"Changed Type"[Column1])},
type table[Column1=text, shiftedCol1 =text]),
//create a column which adds an index number at the first row of each group
//then fill down to create a column on which to group
#"Added Index" = Table.AddIndexColumn(shifted, "Index", 0, 1, Int64.Type),
#"Added Custom" = Table.AddColumn(#"Added Index", "grouper", each if [Column1] <> null and [shiftedCol1] = null then [Index] else null),
#"Removed Columns" = Table.RemoveColumns(#"Added Custom",{"Index"}),
#"Filled Down" = Table.FillDown(#"Removed Columns",{"grouper"}),
#"Removed Columns1" = Table.RemoveColumns(#"Filled Down",{"shiftedCol1"}),
//remove the empty rows
#"Filtered Rows" = Table.SelectRows(#"Removed Columns1", each ([Column1] <> null)),
//group by the "grouper" column
//then transpose each sub table
#"Grouped Rows" = Table.Group(#"Filtered Rows", {"grouper"}, {
{"transpose", each Table.Transpose(Table.SelectColumns(_,"Column1"))}
}),
#"Removed Columns2" = Table.RemoveColumns(#"Grouped Rows",{"grouper"}),
//combine the grouped subtables, and promote the headers
comb = Table.Combine(#"Removed Columns2"[transpose]),
#"Promoted Headers" = Table.PromoteHeaders(comb, [PromoteAllScalars=true]),
#"Changed Type1" = Table.TransformColumnTypes(#"Promoted Headers",
List.Transform(Table.ColumnNames(#"Promoted Headers"), each {_, type text}))
in
#"Changed Type1"
Edit
If, as implied in your comments, there really are NO blank rows between the data sets, but you know the number of columns in the final result,
hard code the number of columns (or set it as a parameter)
change how to construct the "grouper" column by doing an IntegerDivide on the Index column, instead of the formula I used in the above.
M Code
let
Source = Excel.CurrentWorkbook(){[Name="dataTable"]}[Content],
#"Changed Type" = Table.TransformColumnTypes(Source,{{"Data", type text}}),
//hard coded number of columns
numCols = 3,
//add grouper
#"Added Index" = Table.AddIndexColumn(#"Changed Type", "Index", 0, 1, Int64.Type),
#"Inserted Integer-Division" = Table.AddColumn(#"Added Index", "grouper", each Number.IntegerDivide([Index], numCols), Int64.Type),
#"Removed Columns" = Table.RemoveColumns(#"Inserted Integer-Division",{"Index"}),
//group by the "grouper" column
//then transpose each sub table
#"Grouped Rows" = Table.Group(#"Removed Columns", {"grouper"}, {
{"transpose", each Table.Transpose(Table.SelectColumns(_,"Data"))}
}),
#"Removed Columns2" = Table.RemoveColumns(#"Grouped Rows",{"grouper"}),
//combine the grouped subtables, and promote the headers
comb = Table.Combine(#"Removed Columns2"[transpose]),
#"Promoted Headers" = Table.PromoteHeaders(comb, [PromoteAllScalars=true]),
#"Changed Type1" = Table.TransformColumnTypes(#"Promoted Headers",
List.Transform(Table.ColumnNames(#"Promoted Headers"), each {_, type text}))
in
#"Changed Type1"