How to run macro from another workbook - excel

Question

I have a macro in the workbook1 (code below).
I want to run this macro on another workbook, but it keeps opening the workbook1 and create the sheet in workbook1. It works fine if I copy the code into another workbook, but I want to run macro in another workbook from workbook1. The macro will create a sheet in workbook1 using another workbook data. How to make it create the sheet in an active workbook or another workbook.
Sub Pneumatic_Diagram()
Dim FileToOpen As Variant
Dim OpenBook As Workbook
Dim Machine As String
Dim iPnuematic As Integer
Dim iProject As Integer
Dim Lastrow As Long
Machine = Sheets("Project plan").Range("E4")
FileToOpen = "O:\060 Designs\06 All Pneumatic\Pneumatic_Tools\Pneumatic-Database2.xlsx"
With Application
.ScreenUpdating = False
.EnableEvents = False
.Calculation = xlCalculationManual
End With
'*** Delete define sheet name ***
For Each Sheet In ActiveWorkbook.Worksheets
If Sheet.Name = "Pnumatic_Diagram" Then
Sheet.Delete
End If
Next Sheet
'**** Copy GN. from Projectplan****
Sheets("Project plan").Range("B:B").Copy
Sheets.Add(After:=Sheets("Follow up")).Name = "Pnumatic_Diagram"
Sheets("Pnumatic_Diagram").Range("L1").PasteSpecial xlPasteValues
Range("L:L").SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
Range("L:L").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
'**** Get data from data base****
If FileToOpen <> False Then
Set OpenBook = Application.Workbooks.Open(FileToOpen)
OpenBook.Sheets(Machine).Range("A:F").Copy
With ThisWorkbook.Worksheets("Pnumatic_Diagram").Range("A1")
.PasteSpecial Paste:=xlPasteValuesAndNumberFormats
.PasteSpecial Paste:=xlPasteColumnWidths
.PasteSpecial Paste:=xlPasteFormats
End With
OpenBook.Close
End If
'**** Check data***
Cells(1, 7) = 1
For iPnuematic = 1 To Cells(Rows.Count, 2).End(xlUp).Row
For iProject = 1 To Cells(Rows.Count, 12).End(xlUp).Row
If Cells(iPnuematic, 1) = Cells(iProject, 12) Then
Cells(iPnuematic, 7) = 1
End If
Next iProject
Next iPnuematic
'*** Delete GN. project plan ***
Columns(12).EntireColumn.Delete
'*** Clear Data ***
For iPnuematic = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
If Cells(iPnuematic, 7) <> 1 Then
Rows(iPnuematic).EntireRow.Delete
End If
Next iPnuematic
'*** Delete mark 1 ***
Columns(7).EntireColumn.Delete
With Application
.EnableEvents = True
.Calculation = xlCalculationAutomatic
.ScreenUpdating = True
End With
End Sub

Answer 1

Please, try replacing this code part
'*** Delete define sheet name ***
For Each Sheet In ActiveWorkbook.Worksheets
If Sheet.Name = "Pnumatic_Diagram" Then
Sheet.Delete
End If
Next Sheet
with
'your existing code...
'*** Delete define sheet name ***
'create a workbook variable to be set as ActiveWorkbook
Dim wbAct As Workbook: set wbAct = ActiveWorkbook
For Each Sheet In wbAct.Worksheets
If Sheet.Name = "Pnumatic_Diagram" Then
Sheet.Delete
End If
Next Sheet
'your existing code
Then replace ThisWorkbook with wbAct...
Like a general piece of advice, it is good to fully qualify all the used ranges. For instance Sheets("Project plan").Range("B:B").Copy works on the active workbook. To be sure that your code will not open another workbook, which will become the active one, you should use wbAct.Sheets("Project plan").Range("B:B").Copy.
And do the same for all cases where the code works on the active workbook, which may become problematic when the code becomes more complex: Range("L:L"), Cells(1, 7), Cells(iPnuematic, 1) etc.