Excel VBA macro to duplicate data if condition met - excel

Question

this is really advanced level of macro for me. If anyone could help, i really appreciate it!
I have Data as below.
I want to write a macro that looks for the customerID, ex: if C2=C3, then i want it to look for either the row above or below using column D, fill either up or down (ColumnA, ColumnB, and ColumnD) based on how the data came out. Because the data may come out like Row A2 will be emptied or Row A3 will be emptied but each customer can ONLY have 2 row maxed of data lines.

Answer 1

I will answer based on my comment being true. If not it can be updated afterwards.
I simply just took the basics from my answer I gave yesterday and modified it to meet the conditions of this question. You should be able to see the differences and how easily you can change it to do these sort of tasks.
Sub AddMissingInfo()
Dim ws As Worksheet, lrow As Long, arr, i As Long, j As Long
Set ws = Sheets("Sheet1") 'Change to your sheet name
lrow = ws.Range("C" & ws.Rows.Count).End(xlUp).Row 'Use customerID to find last row, change column if needed
arr = ws.Range("A2:D" & lrow).Value 'Populate the array, change columns/starting row if needed
For i = 1 To UBound(arr, 1) - 1 'Stop loop at line before last (alas the -1)
If arr(i, 3) = arr(i + 1, 3) Then 'Check if customer ID matches the row below
If arr(i, 1) = "" Then 'Checks first name
If arr(i + 1, 1) <> "" Then arr(i, 1) = arr(i + 1, 1)
Else
If arr(i + 1, 1) = "" Then arr(i + 1, 1) = arr(i, 1)
End If
If arr(i, 2) = "" Then 'Checks last name
If arr(i + 1, 2) <> "" Then arr(i, 2) = arr(i + 1, 2)
Else
If arr(i + 1, 2) = "" Then arr(i + 1, 2) = arr(i, 2)
End If
If arr(i, 4) = "" Then 'Checks Order#
If arr(i + 1, 4) <> "" Then arr(i, 4) = arr(i + 1, 4)
Else
If arr(i + 1, 4) = "" Then arr(i + 1, 4) = arr(i, 4)
End If
End If
Next i
ws.Range("A2:D" & lrow).Value = arr 'Dump the info back to the range. Change columns/starting row if needed
End Sub