Remove possible trailing spaces from a substring result - string

Question

I am inexperienced in batch scripting and have just have written one where all files in the source directory are enumerated, and each filename string is trimmed up to its first - character. The target path is then checked for the existence of a child directory named using the resulting substring, and if a match is not found, that directory is created. The source file is then moved into that directory.
My issue is that often the filename string contains whitespace immediately preceding the - which results in substrings with trailing space characters.
So my question is, how can I remove the trailing space characters before using the substring containing them.
The code so far:
REM CODE BY ZF
#Echo off
CLS
setlocal
SETLOCAL ENABLEDELAYEDEXPANSION
set /p Input=ENTER DIRECTORY:
REM set mypath=%Input%
REM *******************
REM IFIXED PATH FOR TESTING
set mypath=C:\Admin\cmd_tests
REM echo !mypath!
REM pause
IF "%mypath%" NEQ "" (
REM set mypath=C:\Admin\cmd_tests
REM pause
REM *******************
REM GET SUBFOLDERNAME FROM FILENAME - WORKS
set Counter=0
for %%f in (%mypath%\*.*) do (
echo %%f
echo %%~nxf
for /f "delims=-" %%i in ("%%~nxf") do (
REM echo %%i
set myfolder=%%i
set %%myfolder=myfolder
)
echo !myfolder!
REM set "MYSTRING=%%myfolder"
REM *******************
REM ITERATE FOLDER NAME - myfolder is not transfered into this routine, so the result = "" and ""
(echo %myfolder%& echo.) | findstr /O . | more +1 | (set /P RESULT= & call exit /B %%RESULT%%)
set /A STRLENGTH=%ERRORLEVEL%-5
echo string !myfolder! length = %STRLENGTH%
REM *******************
REM DEFINE TARGET SUBFOLDER PATH
set searchfolder="C:\Admin\cmd_tests\!myfolder!"
echo !searchfolder!
REM if exist !searchfolder! echo "Folder already exists"
REM if not exist !searchfolder! echo "Folder does not exist"
REM *******************
REM CREATE SUBFOLDER
if not exist !searchfolder! mkdir !searchfolder!
REM *******************
REM DEFINE FILE
set targetfile="C:\Admin\cmd_tests\!myfolder!\%%~nxf"
echo !targetfile!
REM *******************
REM MOVE FILE TO SUBFOLDER
IF NOT EXIST "%searchfolder%\%%~NXF" (
echo "FILE DOES NOT EXIST"
REM move "%%f" "%targetfile%"
) ELSE (
echo "FILE EXISTS"
)
echo "---------------------"
)
pause
) ELSE (
REM *******************
REM IF MYPATH DIESN EXIST (user input later)
echo "exit"
pause
)

Answer 1

The following batch file could be used to move all non-hidden files in the specified folder into subfolders with name being either entire file name or the string up to first hyphen character working also for unusual file names starting with a dot and do not have a file extension (= one more dot and at least one other character after last dot).
The Windows file management removes trailing spaces and dots from file/folder names as documented by Microsoft on page about Naming Files, Paths, and Namespaces. For that reason the batch file makes use of the Windows file management functions to get the folder name without trailing spaces and dots instead of using own code to remove trailing spaces from the folder name on file name being something like album name - song title.mp4 to move the file to the subfolder with the name album name.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
cls
rem Assign the first argument string passed to the batch file
rem on calling it to the environment variable FolderPath.
set "FolderPath=%~1"
rem Is the batch file not called with an argument string?
if not defined FolderPath goto FolderPrompt
rem Replace all slashes by backslashes in the passed argument string.
set "FolderPath=%FolderPath:/=\%"
rem Append a backslash if the passed argument string does not end
rem with a backslash and check next if the passed argument string
rem references an existing folder at all.
if not "%FolderPath:~-1%" == "\" set "FolderPath=%FolderPath%\"
if not exist "%FolderPath%" goto FolderPrompt
rem Get the full folder path with a backslash at end
rem if the passed folder path is a relative path.
for %%I in ("%FolderPath%") do set "FolderPath=%%~fI"
goto ProcessFiles
:FolderPrompt
rem Undefine the environment variable FolderPath.
set "FolderPath="
rem Prompt the user for the folder path.
set /P "FolderPath=Enter directory: "
rem Has the user not entered a string?
if not defined FolderPath goto FolderPrompt
rem Remove all double quotes from user input string.
set "FolderPath=%FolderPath:"=%"
rem Has the user not entered anything else than one or more double quotes?
if not defined FolderPath goto FolderPrompt
rem Replace all slashes by backslashes in user input string.
set "FolderPath=%FolderPath:/=\%"
rem Append a backslash if the passed argument string does not end
rem with a backslash and check next if the passed argument string
rem references an existing folder at all.
if not "%FolderPath:~-1%" == "\" set "FolderPath=%FolderPath%\"
if not exist "%FolderPath%" goto FolderPrompt
rem Get the full folder path with a backslash at end
rem if the entered folder path is a relative path.
for %%I in ("%FolderPath%") do set "FolderPath=%%~fI"
goto ProcessFiles
rem Process all non-hidden files in the folder with first loading into
rem memory the list of file names of the files to move to subfolders to
rem make sure that no file is skipped as it could happen on processing
rem the files just a simple FOR loop on FAT32 or exFAT drives.
rem For each file name the string up to first hyphen characters is
rem interpreted as folder name into which the file should be moved.
rem The entire file name is interpreted as folder name if the file name
rem does not contain a hyphen character at all. The extra IF condition
rem is for file names starting with a dot and not having a file extension
rem like ".Unsual File Name - Test!".
rem The Windows file management removes by default all trailing spaces and
rem dots before passing a file/folder name to the file system. Therefore
rem the Windows file management functions are used implicit to get the
rem folder name as either already existing for the current file or being
rem next created without trailing spaces and dots with using the third
rem FOR loop with loop variable K. The usage of "%%~nxK" results in passing
rem the folder name via Windows file management API to the file system and
rem so this reference expands to folder name as returned by the file system
rem (folder exists) respectively the used Windows file managment function
rem (folder does not exist).
:ProcessFiles
echo Process files in: "%FolderPath:~0,-1%"
for /F "eol=| delims=" %%I in ('dir "%FolderPath%*" /A-D-H /B 2^>nul') do (
if not "%%~nI" == "" (
for /F "eol=| delims=-" %%J in ("%%~nI") do for %%K in ("%%J") do (
md "%FolderPath%%%~nxK" 2>nul
if exist "%FolderPath%%%~nxK\" (
echo Move "%%I" to "%%~nxK" ...
move /Y "%FolderPath%%%I" "%FolderPath%%%~nxK\"
) else echo ERROR: Failed to create directory: "%%~nxK"
)
) else (
for /F "eol=| delims=-" %%J in ("%%~xI") do for %%K in ("%%J") do (
md "%FolderPath%%%~nxK" 2>nul
if exist "%FolderPath%%%~nxK\" (
echo Move "%%I" to "%%~nxK" ...
move /Y "%FolderPath%%%I" "%FolderPath%%%~nxK\"
) else echo ERROR: Failed to create directory: "%%~nxK"
)
)
)
endlocal
Well, this batch file should be obviously used for moving song or video files, but is designed nevertheless for moving any type of files.
The path of the folder with the files to move can be passed to the batch file as first argument on calling it, for example for using this batch file via the Send to context menu in Windows File Explorer on right clicking on a folder, or can be entered on execution of the batch file. Please read the comments how the batch file makes sure that the passed or entered argument string is the name of a folder with full or relative path. The passed or entered folder path can be also something like \MySongs (folder MySongs in root of current drive) or ..\MyVideos (folder MyVideos in parent directory of current directory).
The batch file does not use delayed environment variable expansion and works therefore also with file names containing one or more !. It is designed also for file names beginning unusually with one or more spaces or with a semicolon.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
cls /?
dir /?
echo /?
endlocal /?
for /?
goto /?
if /?
md /?
move /?
rem /?
set /?
setlocal /?
Read the Microsoft documentation about Using command redirection operators for an explanation of 2>nul. The redirection operator > must be escaped with caret character ^ on FOR command line to be interpreted as literal character when Windows command interpreter processes this command line before executing command FOR which executes the embedded dir command line with using a separate command process started in background.

Answer 2

i managed it - files are moved now correctly:
CODE V2 / WIP :
REM CODE BY Zdenek Fajfrlik & adapted info from the forum
#Echo off
CLS
SETLOCAL ENABLEDELAYEDEXPANSION
set /p Input=ENTER DIRECTORY:
REM set mypath=%Input%
REM *******************
REM FIXED PATH FOR TESTING
set mypath=C:\Admin\cmd_tests
IF NOT "%mypath%" == "" (
REM *******************
REM GET SUBFOLDERNAME FROM FILENAME - WORKS
set Counter=0
for %%f in (%mypath%\*.*) do (
REM echo %%f
REM echo %%~nxf
for /f "delims=-" %%i in ("%%~nxf") do (
set MYSTRING=%%i
)
REM *******************
REM TRIM STRING - TRAILING SPACES
REM ::trim right whitespace (up to 100 spaces at the end)
for /f "tokens=* delims= " %%a in ("%MYSTRING%") do set MYSTRING=%%a
for /l %%a in (1,1,100) do if "!MYSTRING:~-1!"==" " set MYSTRING=!MYSTRING:~0,-1!
REM echo !MYSTRING!
REM *******************
REM DEFINE TARGET SUBFOLDER PATH
set searchfolder="C:\Admin\cmd_tests\!MYSTRING!"
echo !searchfolder!
REM if exist !searchfolder! echo "Folder already exists"
REM if not exist !searchfolder! echo "Folder does not exist"
REM *******************
REM CREATE SUBFOLDER
if not exist !searchfolder! mkdir !searchfolder!
REM *******************
REM DEFINE FILE
REM set targetfile=C:\Admin\cmd_tests\!MYSTRING!\%%~nxf
set targetfile="C:\Admin\cmd_tests\!MYSTRING!\%%~nxf"
REM echo !targetfile!
REM *******************
REM MOVE FILE TO SUBFOLDER
IF NOT EXIST "%searchfolder%\%%~NXF" (
echo "FILE DOES NOT EXIST"
echo %%f
echo !targetfile!
move "%%f" !targetfile!
) ELSE (
echo "FILE EXISTS"
)
echo "---------------------"
)
pause
) ELSE (
REM *******************
REM IF MYPATH DOES NOT EXIST (user input later)
echo "exit"
pause
)
Thanx for helping :-)
stan