Excel Visual Basic SpinButton1 does not work on second search - excel

Question

I have a table with name and age and a command button, this button opens the customer search screen. When I search for the name Andrew brings me 3 results, I go to page 3 of 3 and perform a new search, so the arrow doesn't work, do you know where the error might be?
Public MatrizResultados As Variant
Public Total_Ocorrencias As Long
Private Sub btn_Procurar_Click()
If Me.txt_Procurar.Text = "" Then
MsgBox "Enter a name"
Else
Call ProcuraPersonalizada(Me.txt_Procurar.Text)
End If
End Sub
Private Sub Label6_Click()
End Sub
Private Sub Label7_Click()
End Sub
Private Sub SpinButton1_Change()
Dim Linha As Long
Dim TotalOcorrencias As Long
TotalOcorrencias = SpinButton1.Max + 1
Linha = MatrizResultados(SpinButton1.Value)
Label_Registros_Contador.Caption = SpinButton1.Value + 1 & " de " & TotalOcorrencias
TextBox1.Text = Plan1.Cells(Linha, 1).Value
TextBox2.Text = Plan1.Cells(Linha, 2).Value
End Sub
Private Sub ProcuraPersonalizada(ByVal TermoPesquisado As String)
Dim Busca As Range
Dim Primeira_Ocorrencia As String
Dim Resultados As String
'perform the search
Set Busca = Plan1.Cells.Find(What:=TermoPesquisado, After:=Range("A1"), LookIn:=xlFormulas, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If Not Busca Is Nothing Then
Primeira_Ocorrencia = Busca.Address
Resultados = Busca.Row
Do
Set Busca = Plan1.Cells.FindNext(After:=Busca)
If Not Busca.Address Like Primeira_Ocorrencia Then
Resultados = Resultados & ";" & Busca.Row
End If
Loop Until Busca.Address Like Primeira_Ocorrencia
MatrizResultados = Split(Resultados, ";")
SpinButton1.Max = UBound(MatrizResultados)
SpinButton1.Enabled = True
Label_Registros_Contador.Caption = "1 de " & UBound(MatrizResultados) + 1
TextBox1.Text = Plan1.Cells(MatrizResultados(0), 1).Value
TextBox2.Text = Plan1.Cells(MatrizResultados(0), 2).Value
Else
SpinButton1.Enabled = False
Label_Registros_Contador.Caption = ""
TextBox1.Text = ""
TextBox2.Text = ""
MsgBox "No results for '" & TermoPesquisado & "' was found."
End If
txt_Procurar.Text = ""
txt_Procurar.SetFocus
End Sub
Private Sub TextBox2_Change()
End Sub
Private Sub UserForm_Initialize()
SpinButton1.Enabled = False
Label_Registros_Contador.Caption = ""
End Sub

Answer 1

You just need to reset the Spin button, it thinks its still on entry 3 of 3 (you can reverse through the options and then it will be correct when you try and go forwards again).
Add this line:
SpinButton1.Value = 0
Somewhere before you start messing with it, I put it:
MatrizResultados = Split(Resultados, ";")
SpinButton1.Value = 0
SpinButton1.Max = UBound(MatrizResultados)