Create images dynamically in vba and add click function to them - excel

Question

I am trying to dynamically add images to a form in a grid like fashion. The images are from a folder for now then, I'm trying to add a click function to each dynamically created images on the form to execute something but I'm stuck on that part. I am successful in importing the images to a form and showing it in a grid like fashion with the code below I came up with.
Option Explicit
Private Sub Pic2_Click()
'not working :(
MsgBox "worked!!"
End Sub
Private Sub UserForm_Initialize()
Dim img As Object
Dim picSheet As Worksheet
'Add Dynamic Image and assign it to object 'Img'
Dim i, h, t As Integer
' Set picSheet = ThisWorkbook.Worksheets("Themes")
' Dim pictureList As Object
' Dim pics As Shapes
' Dim pic As Shape
' Set pics = ThisWorkbook.Worksheets("Themes").Shapes
Dim picPath As String
t = 10
h = 10
picPath = Dir(Environ("USERPROFILE") & "\Pictures\*pic*") 'getting pictures from picpath folder image names are ranged from "pic1.jpg" to "pic12.jpg"
Do While Not Blank(picPath) ' blank determines if a string is empty (boolean value)
i = i + 1
If i > 1 Then h = h + 90
Set img = Me.Controls.Add("Forms.image.1", picPath, True)
If i Mod 4 = 1 And i > 1 Then 'new row after first 4 images to create grid
t = t + 100
h = 10
End If
With img
.Picture = LoadPicture(Environ("USERPROFILE") & "\Pictures\" & picPath)
.PictureSizeMode = fmPictureSizeModeStretch
.Left = h
.Top = t
.name = Split(picPath, ".")(0)
Debug.Print "name is: " & .name
End With
picPath = Dir
Loop
End Sub

Answer 1

This is my entire solution and it worked for me. I changed a few things by using buttons instead that had the images embedded in them.
Option Explicit
Dim ColTB As Collection
Private Sub UserForm_Initialize()
Dim picPath, path As String
Dim i, h, t As Integer
Dim button As Object
Dim fso As New FileSystemObject
t = 10
h = 10
Set ColTB = New Collection
picPath = Dir(Environ("USERPROFILE") & "\OneDrive\Pictures\Themes\" & "*.jpg")
Do While Not Blank(picPath)
i = i + 1
If i > 1 Then h = h + 120
If i Mod 4 = 1 And i > 1 Then
t = t + 100
h = 10
End If
Set button = Me.Controls.Add("Forms.CommandButton.1", picPath, True)
With button
.Font.Bold = True
.Left = h
.Top = t
.Picture = LoadPicture(Environ("USERPROFILE") & "\OneDrive\Pictures\Themes\" & picPath)
.Height = 72
.Width = 100
End With
ColTB.Add EventObj(button)
picPath = Dir
Loop
End Sub
Function EventObj(obj As MSForms.CommandButton) As Class1
Dim o As New Class1
Set o.buttonClickEvent = obj
Set EventObj = o
End Function
Class1 module
Option Explicit
Public WithEvents buttonClickEvent As MSForms.CommandButton
Private Sub buttonClickEvent_Click()
Dim name, imgpath, sheetName As String
Dim answer
Dim ac As Worksheet
Set ac = ThisWorkbook.ActiveSheet
name = buttonClickEvent.name
answer = MsgBox("You want to apply the " & Split(name, ".")(0) & " theme now?", vbQuestion + vbYesNo + vbDefaultButton2, "Apply Theme")
If answer = vbYes Then
imgpath = Environ("USERPROFILE") & "\OneDrive\Pictures\Themes\" & name
ac.SetBackgroundPicture Filename:=imgpath
End If
End Sub