VBA - sort the data from excel - excel

Question

I'm having an case what i don't know how to deal with that, can someone suggest or give me some idea to solve it ?
Summary: I have an Excel file with 3 columns (Name, user , password), this is an example. As you can see in column A , there are 2 cell with name jack , 1 is his user ID (row 2) , and the other is his password. I wish they can stored in the same row , sth like that cell A2 is jack , cell B2 is his user name (jck), and C2 is his pwd (123).
my code as below
Sub test()
Dim last_row As Long
Dim sh As Worksheet
Dim sh2 As Worksheet
Dim wb As Workbook
Set wb = ThisWorkbook
Set sh = wb.Sheets(1)
Set sh2 = wb.Sheets(2)
Dim rng As Range
last_row = sh.Range("A" & Rows.Count).End(xlUp).Row
last_row2 = sh2.Range("A" & Rows.Count).End(xlUp).Row
MsgBox last_row
For i = 2 To last_row - 1
For j = i + 1 To last_row
If sh.Range("A" & i).Value = sh.Range("A" & j).Value Then
If IsEmpty(Range("B" & i)) Then
sh2.Range("A" & i & ":C" & i).Value = sh.Range("A" & i & ":C" & i).Value
sh2.Range("B" & i).Value = sh.Range("B" & j).Value
End If
If IsEmpty(Range("C" & i)) Then
sh2.Range("A" & i & ":C" & i).Value = sh.Range("A" & i & ":C" & i).Value
sh2.Range("C" & i).Value = sh.Range("C" & j).Value
End If
End If
Next j
Next i
End Sub
Could you please help look ? Any assist will be appreciated.

Answer 1

Your main issue is that you use the same row counter for Sheet2 as you do for Sheet1. Since you will end up with half the number of rows with data in Sheet2, that will result in gaps in Sheet2. You will need a seperate row counter for Sheet2
Another issue is you have several unqualified Range references, so whether this works or not will depend on which sheet is active.
A third issue is you haven't declared all your variables.
You code, refactored
Sub test()
Dim last_row As Long
Dim last_row2 As Long
Dim sh As Worksheet
Dim sh2 As Worksheet
Dim wb As Workbook
Dim rng As Range
Dim i As Long, j As Long
Dim rw2 As Long
Set wb = ThisWorkbook
Set sh = wb.Sheets(1)
Set sh2 = wb.Sheets(2)
last_row = sh.Range("A" & sh.Rows.Count).End(xlUp).Row
last_row2 = sh2.Range("A" & sh2.Rows.Count).End(xlUp).Row
'MsgBox last_row
rw2 = 1
For i = 2 To last_row - 1
For j = i + 1 To last_row
If sh.Range("A" & i).Value = sh.Range("A" & j).Value Then
If IsEmpty(sh.Range("B" & i)) Or IsEmpty(sh.Range("C" & i)) Then
rw2 = rw2 + 1
sh2.Range("A" & rw2 & ":C" & rw2).Value = sh.Range("A" & i & ":C" & i).Value
If IsEmpty(sh.Range("B" & i)) Then
sh2.Range("B" & rw2).Value = sh.Range("B" & j).Value
ElseIf IsEmpty(sh.Range("C" & i)) Then
sh2.Range("C" & rw2).Value = sh.Range("C" & j).Value
End If
End If
End If
Next j
Next i
End Sub