VBA transponded Values not getting recognized by Excel - excel

Question

So I have a VBA macro that lets me use Cells like a Userform.
What it basically does is, that it takes the Values of the defined Range("E2:E11")
and transposes them to the next BlankRow.
So with that the User can easily generate a Matrix that ranges from C16:L100
The VBA Code looks like this:
Sub NeuesKFZ()
Dim sh As Worksheet, arr, lastERow As Long, matchCel As Range
Set sh = ActiveSheet
arr = sh.Range("E2:E11").Value
lastERow = sh.Range("C" & sh.Rows.Count).End(xlUp).Row + 1
If Range("E2") = "" Then
MsgBox "Wählen Sie ein KFZ aus!"
Range("E2").Select
Exit Sub
End If
If lastERow < 16 Then lastERow = 16
'check if the range has not been already copied:
Set matchCel = sh.Range("C16:C" & lastERow - 1).Find(WHAT:=sh.Range("E2").Value, LookIn:=xlValues, Lookat:=xlWhole, MatchCase:=False)
If Not matchCel Is Nothing Then
If MsgBox(sh.Range("E2").Value & " Existiert bereits " & vbCrLf & "Sollen die Daten aktualisiert werden?", vbYesNo) = vbYes Then
sh.Range("C" & matchCel.Row).Resize(1, UBound(arr)).Value = Application.Transpose(arr)
End If
sh.Range("E2:E11").ClearContents
Exit Sub
End If
sh.Range("C" & lastERow).Resize(1, UBound(arr)).Value = Application.Transpose(arr)
sh.Range("E2:E11").ClearContents
End Sub
My Problem is now that excel doesn't seem to know what kind of values are getting transposed to the new cells.
In my case I'm working with Dates and I want to know if a date is within the next three months.
But Excel doesn't recognize that it is working with date values.
Trying to format or delete all formatting doesn't help.
And when I'm trying to use this formula:
=if(and(C16>=$AA16$,C16<=$AB$17),TRUE,FALSE)
Some explenation:
C16 is the value that got transposed by the Macro.
AA16 and AB16 are the starting date and end date.
TRUE and FALSE are just to give me feedback if it works or not.
It just gives me FALSE all the time.
Is there a way to get the Date transposed so Excel still knows that its a Date?
Or Maybe force Excel to handle those values as dates.

Answer 1

Transpose Column
I think I read somewhere that besides the size limitation, Transpose 'doesn't like' dates. Anyway, make the following corrections to your code and copy the function to a standard module of your workbook.
Corrections
Replace arr = sh.Range("E2:E11").Value
with arr = GetRowData(sh.Range("E2:E11")).
Replace sh.Range("C" & matchCel.Row).Resize(1, UBound(arr)).Value = Application.Transpose(arr)
with sh.Range("C" & matchCel.Row).Resize(1, UBound(arr, 2)).Value = arr.
Replace sh.Range("C" & lastERow).Resize(1, UBound(arr)).Value = Application.Transpose(arr)
with sh.Range("C" & lastERow).Resize(1, UBound(arr, 2)).Value = arr
The Function
Function GetRowData( _
ByVal ColumnRange As Range) _
As Variant
If ColumnRange Is Nothing Then Exit Function
With ColumnRange.Columns(1)
Dim rCount As Long: rCount = .Rows.Count
Dim rData As Variant
If rCount = 1 Then
ReDim rData(1 To 1, 1 To 1): rData(1, 1) = .Value
Else
Dim cData As Variant: cData = .Value
ReDim rData(1 To 1, 1 To rCount)
Dim r As Long
For r = 1 To rCount
rData(1, r) = cData(r, 1)
Next r
End If
GetRowData = rData
End With
End Function
EDIT
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Returns a 2D one-based one-row array containing the values
' from a one-column range.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetRowFromColumn( _
ByVal ColumnRange As Range) _
As Variant
If ColumnRange Is Nothing Then Exit Function
With ColumnRange.Columns(1)
Dim rCount As Long: rCount = .Rows.Count
Dim rData As Variant
If rCount = 1 Then
ReDim rData(1 To 1, 1 To 1): rData(1, 1) = .Value
Else
Dim cData As Variant: cData = .Value
ReDim rData(1 To 1, 1 To rCount)
Dim r As Long
For r = 1 To rCount
rData(1, r) = cData(r, 1)
Next r
End If
GetRowFromColumn = rData
End With
End Function
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Returns a 2D one-based one-column array containing the values
' from a one-row range.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetColumnFromRow( _
ByVal RowRange As Range) _
As Variant
If RowRange Is Nothing Then Exit Function
With RowRange.Rows(1)
Dim cCount As Long: cCount = .Columns.Count
Dim cData As Variant
If cCount = 1 Then
ReDim cData(1 To 1, 1 To 1): cData(1, 1) = .Value
Else
Dim rData As Variant: rData = .Value
ReDim cData(1 To cCount, 1 To 1)
Dim c As Long
For c = 1 To cCount
cData(c, 1) = rData(1, c)
Next c
End If
GetColumnFromRow = cData
End With
End Function