Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 1 year ago.
Improve this question
Create a formula that returns only the characters that appear after "X" for the given character strings. The same formula must work for the whole column!
Example of how it should look like after you apply your formula:
765892X329 329
752238X44 44
FIND / SEARCH
Find the position of the "X":
=FIND("X",A1)
An error will occur if there is no "X".
Get the right characters after the "X":
=RIGHT(A1,LEN(A1)-FIND("X",A1))
Handle the error:
=IF(ISNUMBER(FIND("X",A1)),RIGHT(A1,LEN(A1)-FIND("X",A1)),"")
Allow a lower case "x":
=IF(ISNUMBER(SEARCH("X",A1)),RIGHT(A1,LEN(A1)-SEARCH("X",A1)),"")
Convert the resulting text into a number:
=IF(ISNUMBER(SEARCH("X",A1)),VALUE(RIGHT(A1,LEN(A1)-SEARCH("X",A1))),"")
An error will occur if the resulting text is not 'numeric'.
Handle errors differently:
=IFERROR(VALUE(RIGHT(A1,LEN(A1)-SEARCH("X",A1))),"")
Abandon the 'convert to number' idea:
=IFERROR(RIGHT(A1,LEN(A1)-SEARCH("X",A1)),"")
Abandon the 'allow lower case' idea.
=IFERROR(RIGHT(A1,LEN(A1)-FIND("X",A1)),"")
If the range is in Column A and you have office 365 you can use the following:
=MID(FILTER(A:A,A:A<>""),FIND("X",FILTER(A:A,A:A<>""))+1,LEN(FILTER(A:A,A:A<>"")))
Else use:
=MID(A:A,FIND("X",A:A)+1,LEN(A:A)) and drag down.
This works:
=RIGHT(A3,LEN(A3)-FIND("X",A3,1))*1
Assumed is that the first item is in cell A3, then drag down. The *1 is to convert from text to number.
Related
Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 3 years ago.
Improve this question
This is undoubtedly a very simple problem, but I don't have much experience with coding in Excel.
In this example, I would like the user to input the # of students into cell B3.
After inputting the # into the cell (for example, if the person input 5), I would like to create that number of rows from A4-A9 based on the notation Student_# (Student_1, Student_2, Student_3, Student_4, Student_5).
If the person put in 10, I would like there to be 10 rows of Student_1 through Student_10 (updated automatically).
The "Student_" will be static as this is an unidentified list, I'd just like to create the number of rows based on this initial input value.
Thanks in advance for any help.
In A5 put:
=IF(ROW(A1)<=$B$3,"Student_" & ROW(A1),"")
And copy down enough to cover the largest number allowed in B3
If one has the Dynamic Array formula simply put:
="Student_"&SEQUENCE(B3)
In A5 and Excel will spill the results down.
Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 4 years ago.
Improve this question
I am creating a spreadsheet where the user can enter different numbers and have a different result be returned.
For example if they were to enter a number that started 07, it would show 1, 070 it would show 2, 0345 3 and so on.
I have tried the IF and LEFT formulas but I am struggling!
Any ideas are greatly appreciated!
EDIT: Sorry I was trying not to write war and peace but have missed out too much.
The users will write in phone area codes, e.g. 0345 or 0714 or 0701 and the sheet will return the price.
The price can be different depending on the first 4 digits. To keep it simple for this purpose I want it to be able to detect if the area code starts with 07 to show a "price" of 1, 070 price of 2 and 0345 a price of 3.
I have 10 different area codes but just added the 3 above for examples.
I hope this is clearer.
To get the length of a string with the leading zeros removed use the array function
=LEN(MID(A2,MATCH(TRUE,(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)<>"0"),0),LEN(A2)))
Replace A2 with the cell that the users will change and hit [Ctrl Shift Enter] on the cell with the formula to activate the array function.
Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 4 years ago.
Improve this question
I have two tables (more like lists) in an excel doc; both are only one column. I want to create a formula that will search the first list and highlight any cells that contain one of the words in the second list.
For example:
List 1:
dry shampoo
nail polish
leave in conditioner
hand lotion
face mask
List 2:
mask
shampoo
soap
moisturizer
cleanser
conditioner
The formula would search List 1 and highlight the cells "dry shampoo" "leave in conditioner" and "face mask" based on the criteria that the words shampoo, conditioner, and mask are in List 2.
Anyone know if this is possible?
Yup:
=SUMPRODUCT(--ISNUMBER(SEARCH($C$1:$C$6,A1)))>0
Closed. This question needs details or clarity. It is not currently accepting answers.
Want to improve this question? Add details and clarify the problem by editing this post.
Closed 4 years ago.
Improve this question
I want to fuse 3 items to one using concatenate formula. I am trying to fuse date (2018-06-08) and 2 normal text items (12 and 45). I use this formula =Concatenate(D2;" ";E2;":";F2) But when I fuse them, I get 43259 12:45, instead of 2018-06-08 12:45. I tried adding TEXT but it only gave me error.
Try,
=D2+time(E2, F2, 0)
Format the result as you prefer. e.g. yyyy-mm-dd hh:mm
Use this:
=CONCATENATE(TEXT(D2,"yyyy-mm-dd"), " ", E2, ":", F2)
Because Google docs (like Excel) represents dates with a number (usually it's the number of days since 1900-01-01), you need to convert it to text format with special instructions specifying the order of day, month, year, and what punctuation to separate them.
Currently the documentation for the TEXT function can be found here.
Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 7 years ago.
Improve this question
So I need a function that allows me to convert a 00:90:7f:b3:ff:02 to 00907fb3ff02
then from there to the first six characters to = 00907f. After that I need it to do a vlookup to a second worksheet and match for example
Samsung 00907f
I know how to do these things all separately with left, substitute and vlookup. Is there a way to make this into one vba function? is this even possible?
You can use this part of formula in your vlookup:
LEFT(SUBSTITUTE(A1,":",""),6)
Replace A1 with the cell reference of the MAC Address
What this will do is show the first Left 6 characters of the Mac address but before we show it, it will use substitute to remove any: :
Hope this helps.