Composing groovy closures with multiple parameters - groovy

Question

I'm trying to create a simple groovy script that will download some JSON from a website, pretty print it, and then save it to a file. I'm using this as an exercise to learn how to practice some functional concepts and I'm running into an issue I can't figure out. Basically, the last composed closure has multiple params and I can't figure out how to apply it. I'd like the end result to be a one liner that specifies the URL and file location to save the contents.
def getJson = { sourceUrl ->
def conn = new URL(sourceUrl).openConnection() as HttpURLConnection
return conn.inputStream.text
}
def prettyPrintJson = { json ->
return groovy.json.JsonOutput.prettyPrint(json)
}
def save = { data, fileLocation ->
new File(fileLocation).write(data)
}
def sync = getJson >> prettyPrintJson >> save
sync('https://jsonplaceholder.typicode.com/posts') // don't know how to specify the fileLocation

Answer 1

If you compose functions, your innermost function determines the
arguments. So you could provide the second argument to save via
rcurry. E.g.:
def sync = getJson >> prettyPrintJson >> save.rcurry("/tmp/out.json")
sync('https://jsonplaceholder.typicode.com/posts')
Or you would have to thread the second argument down the line until you
need it. E.g.:
def getJson = { sourceUrl, out ->
[sourceUrl.toURL().text, out]
}
def prettyPrintJson = { json, out ->
[groovy.json.JsonOutput.prettyPrint(json), out]
}
def save = { data, fileLocation ->
new File(fileLocation).write(data)
}
def sync = getJson >> prettyPrintJson >> save
sync('https://jsonplaceholder.typicode.com/posts', '/tmp/out.json')
I'd imagine, that by using a macro (since 2.5) there should be a chance to
create a threading macro (e.g. like in Clojure).