How to exit multiple macros if file isnt located? - excel

Question

Call_Process call multiple macros, each one of them dependent on the previous macro. first macro gets the file location, followed by opening the file in that folder and the final one to close and save changes. The issue is if the opening file isn't there, the following macro will error out. How do I cancel the entire Call_Process if the file isn't located?
Sub Call_Process ()
Call File_Location
Call Open_File
Call Exit_WB
End Sub
**Sub File_Location ()**
location_db = "C:\Users\Documents\New folder\*.xl??"
End Sub ()
**Sub Open_File ()**
dim wb as Workbook
dim ws as Worksheet
if dir(location_db) = "" <- as you can see if the file doesnt exists, it exits out of Open_File sub but not the Exit_WB when im running the Call_Process
end sub
end if
wb_filename = wb.name
sheet_name = ws.name
End Sub
**Sub Exit_WB**
Workbooks(location_db).close savechanges=TRUE
End Sub

Answer 1

Truth be told, you'd need a bit more structure to your application. I don't think it's good practice to call SubProcedures that update global variables (unless there's a specific need for that). Take a look at my below example. Call_Process first asks a function for a file path. If it doesn't get one, the subroutine handles its own error messages. Once the path is available, it calls a function to open a workbook and leave a reference to said workbook. Again, if it doesn't work, the sub can handle it on its own.
Let me know if this helps out.
Sub Call_Process()
Dim filePath As String
Dim wb As Workbook
filePath = GetDatabaseLocation()
If filePath = vbNullString Then
MsgBox "No File"
Exit Sub
End If
Set wb = GetDatabaseWorkbook(filePath)
If wb Is Nothing Then
MsgBox "Sorry, couldn't open this file."
Exit Sub
End If
'Process whatever
wb.Close SaveChanges:=True
End Sub
Private Function GetDatabaseLocation() As String
Dim loc As String
Dim fullPath As String
loc = "c:\TempPath\*.xl??"
'If the file doesn't exist, it will return an empty string
'Otherwise, the file location. NOTE: DIR() returns only the file
'name, so we will append the path below
fullPath = Dir(loc)
If fullPath <> vbNullString Then
fullPath = "c:\TempPath\" & fullPath
End If
GetDatabaseLocation = fullPath
End Function
Private Function GetDatabaseWorkbook(sFilename As String) As Workbook
Dim wb As Workbook
'If there is an error or something, will return 'Nothing'
On Error Resume Next
Set wb = Workbooks.Open(sFilename)
On Error GoTo 0
Set GetDatabaseWorkbook = wb
End Function

Answer 2

You can code with on error also, should be working if error trigger:
Sub Call_Process ()
On Error GoTo ErrorHandler:
Call File_Location
Call Open_File
Call Exit_WB
Exit Sub
ErrorHandler:
End Sub

Answer 3

when you say cancel out... you can use 'END' in the code. This will stop the entire code from running. one note, it wont actually tell you it's stopped so you might want to add a comment as a messagebox or immediate window. code would look something like this:
Sub Call_Process()
Call File_Location
Call Open_File
Call Exit_WB
End Sub
Sub File_Location()
location_db = "C:\Users\Documents\New folder\*.xl??"
End Sub
Sub Open_File()
Dim wb As Workbook
Dim ws As Worksheet
If Dir(location_db) = "" Then
MsgBox "no file location"
End
End If
wb_filename = wb.Name
sheet_name = ws.Name
End Sub
Sub Exit_WB()
Workbooks(location_db).Close savechanges = True
End Sub
Now if you want to expand and get specific messages, i would recommend you change them into functions with outputs/error handling.