Filter Date with VBA - excel

Question

[I need some help how to count date in another workbook with VBA.
Sub countMacro()
Dim oWBWithColumn As Workbook: Set oWBWithColumn = Application.Workbooks.Open("D:\U2000\Taishan01\Dump\Taishan01_0428.xlsx")
Dim oWS As Worksheet: Set oWS = oWBWithColumn.Worksheets("CurrentAlarms20210428102131871_")
Dim intLastRow As Long: intLastRow = oWS.Cells(Rows.Count, "J").End(xlUp).Row
ThisWorkbook.Worksheets("Sheet1").Range("D2").Value = Application.WorksheetFunction.CountA(oWS.Range("J7:J" & intLastRow), "<2021")
oWBWithColumn.Close False
Set oWS = Nothing
Set oWBWithColumn = Nothing
End Sub
This is my code I want filter date <2021 and between 2 date 01-01-2021 to 04-01-2021. Please kindly help. Because I want to try is can't run.

Answer 1

When you will have the range converted to Date, please use the next (adapted) code:
Sub countMacro()
Dim oWBWithColumn As Workbook: Set oWBWithColumn = Application.Workbooks.Open("D:\U2000\Taishan01\Dump\Taishan01_0428.xlsx")
Dim oWS As Worksheet: Set oWS = oWBWithColumn.Worksheets("CurrentAlarms20210428102131871_")
Dim intLastRow As Long: intLastRow = oWS.cells(oWS.rows.count, "J").End(xlUp).row
Dim firstD As Long, endD As Long, rng As Range
Set rng = oWS.Range("J7:J" & intLastRow)
firstD = CLng(DateSerial(2021, 1, 1))
endD = CLng(DateSerial(2021, 4, 1))
ThisWorkbook.Worksheets("Sheet1").Range("D2").value = WorksheetFunction.CountIfs(rng, ">=" & firstD, rng, "<=" & endD)
oWBWithColumn.Close False
End Sub
Edited:
In order to convert your text looking like Date, in Date, please use the next code:
Sub TransformTextInDate()
Dim sh As Worksheet, lastR As Long, rngT As Range, arrT, ArrD, arr, i As Long
Set sh = ActiveSheet 'use here the sheet you need, or activate the one to be processed
lastR = sh.Range("J" & sh.rows.count).End(xlUp).row
Set rngT = sh.Range("J7:J" & lastR) 'use here your range to be converted in Date
arrT = rngT.value 'load the range in an array
ReDim ArrD(1 To UBound(arrT), 1 To 1) 'redim the array to keep Date
For i = 1 To UBound(arrT)
arr = Split(arrT(i, 1), "-") 'split the text by "-"
ArrD(i, 1) = CDate(left(arr(2), 2) & "/" & arr(1) & "/" & arr(0)) 'build the Date
Next i
rngT.Offset(0, 1).EntireColumn.Insert xlLeft 'insert a column to the right of the processed one
With sh.cells(rngT.row, rngT.Offset(0, 1).Column).Resize(UBound(ArrD), 1)
.Value2 = ArrD 'drop the processed array values at once
.EntireColumn.AutoFit 'fit the new column
.NumberFormat = "dd/mm/yyyy" 'format the range in the standard way
End With
MsgBox "Converted to Date..."
End Sub
The above code will insert a column and drop the processed result in it.
If the conversion is correct, you may delete the previous column, or if you like keeping it (for hours or for something else), you should adapt the first code to make it working on the new column (please, change J to K).
Please, send some feedback after testing the above codes.