VBA isEmpty() - Check if cells are empty and tell me which ones - excel

Question

Apologies if this has been answered already, I did search and can't seem to find an answer:
How could I change the code below to check for empty cells across two sheets and not in a continuous range and to tell me which cells are blank.
The range will be sheet "Request" Range, B5,B6,B7,b10,b11 & sheet "Data" Range A8, B8, D8,
Is it possible for the code to tell me the adjacent Cell name so can find it and put a value in, for example B5, A5 is called "request name" so I'd need to highlight to the user request name is blank for them to go and put a value and so on for the other cells.
Sub check_empty()
Dim i As Long
Dim c As Long
Dim myRange As Range
Dim myCell As Range
Set myRange = Sheets("Request").Range("B5:B8")
For Each myCell In myRange
c = c + 1
If IsEmpty(myCell) Then
i = i + 1
End If
Next myCell
MsgBox _
"There are total " & i & " empty cell(s) out of " & c & "."
End Sub

Answer 1

Is it correct the range for sheet "Data"?
Cause Range A8 won't have a named range adjacent to it, and B8 would have A8 as its named range... anyway, here's what I came up with:
Sub check_empty()
Dim c As Integer
Dim i As Integer
Dim sReport As String
Dim rResults() As String
c = 0
i = 0
Call loop_check_empty("Request", "B5:B7,B10:B11", rResults, c, i)
Call loop_check_empty("Data", "A8,B8,D8", rResults, c, i)
sReport = Join(rResults, vbCr)
MsgBox "There are total " & i & " empty cell(s) out of " & c & "." & vbCr & sReport
End Sub
Sub loop_check_empty(ByVal sSheet As String, ByVal sRange As String, ByRef rResults() As String, ByRef c As Integer, ByRef i As Integer)
Dim myCell, myRange As Range
Dim sColumn, sRow As String
Set myRange = Sheets(sSheet).Range(sRange)
For Each myCell In myRange
c = c + 1
If IsEmpty(myCell) Then
i = i + 1
ReDim Preserve rResults(1 To i)
sColumn = Mid(myCell.Address, 2, 1)
sRow = Mid(myCell.Address, 4, Len(myCell.Address))
Sheets(sSheet).Range(sColumn & sRow).Interior.Color = vbRed
If sColumn = "A" Then
rResults(i) = sColumn & sRow
Else
rResults(i) = sColumn & sRow & " for "
sColumn = Chr(Asc(sColumn) - 1)
rResults(i) = rResults(i) & Sheets(sSheet).Range(sColumn & sRow).Name.Name
End If
End If
Next myCell
End Sub
Assuming the ranges A5, A6, A7, A10 and A11, in sheet "Request" are named ranges.
And ranges A8 and C8 in sheet "Data".
The code will turn sheet "Request" Range, B5,B6,B7,b10,b11 & sheet "Data" Range A8, B8, D8 all into red, so the user will know where to enter data.
And the msgbox will report the empty ranges, as well as the named range adjacent to it.