Adding 1 to ColB while looking at values of ColA - excel

Question

I have been trying to looping through a range to add 1 in ColB while looking at ColA values and I want to add 1 from high to low values where 0 will be empty.
Your help will be appreciated.
My try.
Dim lastRow As Integer
lastRow = Sheet1.Cells(Rows.Count, 1).End(xlUp).Row
If Sheet1.Range("A2" & lastRow).Value > 0 Then
Range("B2" & lastRow).Value = 1
ElseIf Sheet1.Range("A2").Value = 0 Then
Range("B2" & lastRow).Value = ""
End If
2nd try
Dim lastRow As Integer
lastRow = Sheet1.Cells(Rows.Count, 1).End(xlUp).Row
Dim c As Range
For Each c In Range("A2:A50")
If c.Value > 0 Then
Sheet1.Range("B2" & lastRow).Value = 1
End If
Next c
like this

Answer 1

Write to Column If the Value in Another Column is Not Equal to 0
Note that both solutions do the same.
For the array version, it is assumed that the range has at least two cells (A2:A3). If A2:A2, it will fail.
Option Explicit
Sub SlowRange()
Dim LastRow As Long
LastRow = Sheet1.Cells(Sheet1.Rows.Count, 1).End(xlUp).Row
Dim rg As Range: Set rg = Sheet1.Range("A2:A" & LastRow)
Dim c As Range
For Each c In rg.Cells
If c.Value <> 0 Then
c.Offset(, 1).Value = 1
'Else
' c.Offset(, 1).Value = Empty
End If
Next c
End Sub
Sub FastArray()
Dim LastRow As Long
LastRow = Sheet1.Cells(Sheet1.Rows.Count, 1).End(xlUp).Row
Dim rg As Range: Set rg = Sheet1.Range("A2:A" & LastRow)
Dim Data As Variant: Data = rg.Value
Dim r As Long
For r = 1 To UBound(Data, 1)
If Data(r, 1) <> 0 Then
Data(r, 1) = 1
Else
Data(r, 1) = Empty
End If
Next r
rg.Offset(, 1).Value = Data
End Sub