Spreadsheet not found in the workbook, even if that spreadsheet exists - excel

Question

I have this small piece of code:
NombreLibro = Application.GetOpenFilename()
Set Libro = Workbooks.Open(NombreLibro, , False)
If Val(Application.Version) > 15 Then 'I tried this but it doesn't solve the problem
Libro.AutoSaveOn = False
End If
With Libro
For i = 1 To .Worksheets.Count
If .Worksheets(i).CodeName = "Sheet1" Then 'HERE I HAVE THE PROBLEM
(doing something)
End If
Next i
End With
Sometimes the "if" is false even if the workbook actually has the "Sheet1".
But if I run this again, adding a stop in the code to check what is going on, then the piece of code works as expected.
I am downloading the workbooks from a company website and run the code right away.
I have OneDrive in my computer. So I am wondering if OneDrive is busy uploading the file and then Excel doesn't access it correctly?
What do you suggest I could try?
EDIT:
Following VBasic2008 suggestion (see his/her answer) I changed a little the code, but it kept failing. I then added a debug MsgBox:
For Each ws In Libro.Worksheets
MsgBox "CodeName: " & ws.CodeName & vbLf _
& "Name: " & ws.Name & vbLf & "Libro: " & Libro.Name 'I added this
If ws.CodeName = wsCodeName Then
wasFound = True
Exit For ' The worksheet is found, no need to loop anymore.
End If
Next ws
Result (shown in the MsgBox):
CodeName: 'blank!!!
Name: SheetName 'correct
Libro: LibroName 'correct
Is there a bug in Excel related to CodeNames?
EDIT2: (WORKAROUND)
I download the files from a company website, the data on the website is on a table and then a converter downloads it into Excel format.
I think the downloaded file is not quite Excel format and the CodeName is not filled. When Excel opens it and then the VBA editor is opened, Excel fills out the CodeName with a standard name.
In my case, as the fresh downloaded files have only one sheet, I can use this workaround:
For Each ws In Libro.Worksheets
If ws.CodeName = wsCodeName Or ws.CodeName = "" Then
wasFound = True
Exit For
End If
Next ws
This will work the first time the file is processed ws.CodeName = "" and the next times ws.CodeName = wsCodename

Answer 1

Using Worksheet CodeName
Option Explicit
Sub testCodeName()
Const wsCodeName As String = "Sheet1"
' Choose file (workbook, spreadsheet).
Dim NombreLibro As Variant
NombreLibro = Application.GetOpenFilename()
' Validate workbook.
If NombreLibro = False Then
MsgBox "You canceled.", vbExclamation, "Canceled"
Exit Sub
End If
' Open and create a reference to the workbook.
Dim Libro As Workbook: Set Libro = Workbooks.Open(NombreLibro, , False)
' Attempt to find the worksheet.
Dim ws As Worksheet
Dim wasFound As Boolean
For Each ws In Libro.Worksheets
If ws.CodeName = wsCodeName Then
wasFound = True
Exit For ' The worksheet is found, no need to loop anymore.
End If
Next ws
' Validate worksheet.
If Not wasFound Then
MsgBox "Worksheet not found.", vbExclamation, "Not Found"
Exit Sub
End With
' Continue with the code
With ws
' e.g. see if it's true.
MsgBox "Worksheet found:" & vbLf _
& "Name: " & .Name _
& vbLf & "CodeName: " & .CodeName, vbInformation, "Success"
End With
End Sub

Answer 2

I'm somewhat of a VBA noob but I wrote this simple code a while back to search for a worksheet and delete it:
Dim sht As Worksheet
For Each sht In ThisWorkbook.Worksheets
If Application.Proper(sht.Name) = Application.Proper("Company Data") Then
Sheets("Company Data").Select
Application.DisplayAlerts = False
ActiveWindow.SelectedSheets.Delete
Application.DisplayAlerts = True
End If
Next sht
Maybe this can help?