Using the same macro in a different spreadsheet - excel

Question

For testing macro purposes, I am trying to do the following command on the spreadsheet ( Copy/highlight existing data in a given spreadsheet and then try to sort). However, when i tried to apply the same macro in another new workbook. I know in the following command- it is only locked to Worksheets("sheet1")- how should i change this so that i can apply in other excels(new workbooks) that have a different name as well?
Cells. Select
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add2 Key:=Range("A2:A3") _
, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("Sheet1").Sort
.SetRange Range("A2:B3")
.Header = xlGuess
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
End Sub
many thanks!

Answer 1

Sort 'Pattern' for Different Worksheets
The first procedure is an example of how to use the second one (the solution).
Replace Sheet1 with the name of your worksheet.
Option Explicit
Sub sortWorksheetTEST()
Dim wb As Workbook
' Pick one:
Set wb = ThisWorkbook ' the workbook containing this code
'Set wb = ActiveWorkbook ' an active workbook, the one you're looking at
'Set wb = Workbooks("Test.xlsx") ' an open workbook
'Set wb = Workbooks.Open("C:\Test\Test.xlsx") ' a workbook to be opened
Dim ws As Worksheet: Set ws = wb.Worksheets("Sheet1")
sortWorksheet ws
' or e.g. without any of the previous
'sortWorksheet ActiveSheet
End Sub
Sub sortWorksheet(ByVal ws As Worksheet)
On Error GoTo clearError
ws.Sort.SortFields.Clear
ws.Sort.SortFields.Add2 Key:=ws.Range("A2:A3"), SortOn:=xlSortOnValues, _
Order:=xlAscending, DataOption:=xlSortNormal
With ws.Sort
.SetRange ws.Range("A2:B3")
.Header = xlGuess ' you don't want VBA to decide: xlYes or xlNo
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
ProcExit:
Exit Sub
clearError:
MsgBox "Run-time error '" & Err.Number & "':" & Err.Description
Resume ProcExit
End Sub