Puppet install DS with 2 different commands and only if - puppet

Question

I am not very experienced in Puppet and I really need your help.
I have 2 servers where I need to install DS (ed. Directory Server) . Is running without error but in the servers not run these commands. What I made wrong?
exec { 'Install first DS':
command => "setup --serverId first-ds --deploymentKeyPassword ${prof_ds::constants::deployment_pwd} --deploymentKey ${prof_ds::constants::deployment_key} --rootUserDn ${prof_ds::constants::admin_user} --rootUserPassword ${prof_ds::constants::admin_pwd} --monitorUserPassword ${prof_ds::constants::monitor_pwd} --hostname ${::fqdn} --ldapPort ${prof_ds::constants::ldap_port} --ldapsPort ${prof_ds::constants::ldaps_port} --httpsPort ${prof_ds::constants::https_port} --adminConnectorPort ${prof_ds::constants::admin_port} --replicationPort ${prof_ds::constants::replication_port} --start --acceptLicense",
onlyif => ['test "${::fqdn}" == "${ds_hosts[0]}" && echo 0 || echo 1'],
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
}
exec { 'Install second DS':
command => "setup --serverId second-ds --deploymentKeyPassword ${prof_ds::constants::deployment_pwd} --deploymentKey ${prof_ds::constants::deployment_key} --rootUserDn ${prof_ds::constants::admin_user} --rootUserPassword ${prof_ds::constants::admin_pwd} --monitorUserPassword ${prof_ds::constants::monitor_pwd} --hostname ${::fqdn} --ldapPort ${prof_ds::constants::ldap_port} --ldapsPort ${prof_ds::constants::ldaps_port} --httpsPort ${prof_ds::constants::https_port} --adminConnectorPort ${prof_ds::constants::admin_port} --replicationPort ${prof_ds::constants::replication_port} --bootstrapReplicationServer ${ds_hosts[0]}:${prof_ds::constants::replication_port} --start --acceptLicense",
onlyif => ['test "${::fqdn}" == "${ds_hosts[1]}" && echo 0 || echo 1'],
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
}

Answer 1

I presume your commands are correct. So what may need to be fixed is the onlyif command, that means that the exec command is going to be ran onlyif it will return a non-zero output (more). The command will run and will interpolate when using double-quote and will not if used single quote (is a Ruby standard rather than Puppet)
The full code:
if $::hostname == $ds_hosts[0] {
exec { 'setup first-ds':
command => "setup --serverId first-ds --deploymentKeyPassword ${prof_ds::constants::deployment_pwd} --deploymentKey ${prof_ds::constants::deployment_key} --rootUserDn ${prof_ds::constants::admin_user} --rootUserPassword ${prof_ds::constants::admin_pwd} --monitorUserPassword ${prof_ds::constants::monitor_pwd} --hostname ${::fqdn} --ldapPort ${prof_ds::constants::ldap_port} --ldapsPort ${prof_ds::constants::ldaps_port} --httpsPort ${prof_ds::constants::https_port} --adminConnectorPort ${prof_ds::constants::admin_port} --replicationPort ${prof_ds::constants::replication_port} --start --acceptLicense",
onlyif => ["test '${::fqdn}' == '${ds_hosts[0]}' && echo 0 || echo 1"],
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
}
}
if $::hostname == $ds_hosts[1] {
exec { 'setup second-ds':
command => "setup --serverId second-ds --deploymentKeyPassword ${prof_ds::constants::deployment_pwd} --deploymentKey ${prof_ds::constants::deployment_key} --rootUserDn ${prof_ds::constants::admin_user} --rootUserPassword ${prof_ds::constants::admin_pwd} --monitorUserPassword ${prof_ds::constants::monitor_pwd} --hostname ${::fqdn} --ldapPort ${prof_ds::constants::ldap_port} --ldapsPort ${prof_ds::constants::ldaps_port} --httpsPort ${prof_ds::constants::https_port} --adminConnectorPort ${prof_ds::constants::admin_port} --replicationPort ${prof_ds::constants::replication_port} --bootstrapReplicationServer ${ds_hosts[0]}:${prof_ds::constants::replication_port} --start --acceptLicense",
onlyif => ["test '${::fqdn}' == '${ds_hosts[1]}' && echo 0 || echo 1"],
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
}
}
UPDATE:
Another optimization I recommend is avoid testing empty strings (depends on the OS/version), by adding another char in front, e.g. x:
test 'x${::fqdn}' == 'x${ds_hosts[0]}' && echo 0 || echo 1
UPDATE:
More on how you can restrict exec on specific nodes (more), in a very simple empirical way (updated the code snippet above, too)
However, the proper way to restrict specific execution on specific nodes, is to either have 2 Nodegroups: Directory Service Primary and Directory Service Secondary, pin each node to its counterpart, and use the resource collector feature to distribute the work on different nodes.
Another note is that you should avoid using exec resource as they are not idempotent. If that is not possible, to define a type that would wrap that resource and manage all of its lifecycle. In your case would be something like:
directory_service { 'first-ds':
deploymentKeyPassword => '?',
deploymentKey => '?',
}
This would probably come later, when you understand how do you want to manage the configurations of your DS service. To get inspired, check apache. Looking on forge for DS, one module raised my attention: markt-de/puppet-ds_389

Answer 2

Your onlyif attributes are nonsense on several levels. Your other answer points out some of these, but for completeness:
An Exec's onlyif attribute should be a single command, as a string. You may be lucking out via stringification of the arrays you are actually presenting, but you really ought to make them plain strings.
By putting the onlyif command in single quotes, you prevent Puppet from interpolating values for the Puppet variable references within.
You appear to have the idea that it is the standard output of the onlyif command that determines whether the main command will be run, but that is incorrect: it is the onlyif's exit status.
Since all the details being tested are known during catalog building, it is pointless to use an onlyif attribute at all. A Puppet conditional statement would be better suited.
But what you should use an unless or onlyif or creates for is to prevent installing the software again if it has already been installed.
Overall, then, you want something more like this:
if $::fqdn == $ds_hosts[0] {
exec { 'Install first DS':
command => "setup --serverId first-ds ...",
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
unless => "exit_with_status_0_if_DS_is_already_installed",
}
} elsif $::fqdn == $ds_hosts[1] {
exec { 'Install second DS':
command => "setup --serverId second-ds ...",
environment => ["JAVA_HOME=${java_home}"],
path => ['/usr/bin', '/usr/sbin', '/bin', '/opt/opendj','/opt/opendj/bin'],
unless => "exit_with_status_0_if_DS_is_already_installed",
}
}